访问记录中的字段时出现语法错误

Question

我遇到了一个应该很容易解决的问题。在此之后，我尝试访问记录中的字段。这是一个展示我的问题的简化示例：

-module(test).
-export([test/0]).

-record(rec, {f1=[], f2=[], f3=[]}).

test() ->
    Rec = #rec{f1=[1,2,3], f3=[4,5,6]},
    Fields = record_info(fields, rec),
    loop(Fields, Rec).

loop([Field|Fields], Rec) ->
    [Rec#rec.Field|loop(Fields, Rec)]; %% <-- This is line 12.
loop([], _Rec) ->
    [].

当我尝试编译测试时，我收到语法错误：

./test.erl:12: syntax error before: Field

我做错了什么？

Answer 1

如果您只想枚举记录值，可以使用 element/2 和枚举从 2 （第一个元素是记录名称）到 < a href="http://www.erlang.org/doc/man/erlang.html#tuple_size-1" rel="nofollow">tuple_size（记录）。

如果您想在运行时按名称访问记录字段，您可以在编译时创建辅助 proplist，如下所示：

Fields = lists:zip(record_info(fields, rec),
                   lists:seq(2, record_info(size, rec)))

请注意，record_info() 始终在编译时求值。

然后使用类似于以下的函数查询字段值这：

get_record_value(Name, Record, Fields) ->
    case proplists:get_value(Name, Fields) of
        undefined ->
            undefined;
        N when is_integer(N) ->
            element(N, Record)
    end.

Answer 2

记录在编译时转换为数组，这意味着所有字段访问也都转换为 erlang:element 调用。因此变量不能用作字段名称必须在编译时已知 - 正如 Damg 已经回答的那样。

我知道的“解决方法”要么使用 proplists、dicts 等而不是记录，要么使用 Ulf Wiger 的 exprecs< /a> 生成记录访问函数。

Answer 3

另一种方法是将记录转换为 proplist 并使用 proplists 库模块来迭代或访问特定字段。此示例：

-module(test).
-export([start/0]).
-record(test, {value1, value2, value3}).

start() ->
    R = #test{value1=1, value2=2, value3=3},
    Fields = record_info(fields, test),
    Values = tl(tuple_to_list(R)),
    lists:zip(Fields, Values).

将生成以下 proplist：

> c("test").
> Proplist = test:start().
[{value1,1},{value2,2},{value3,3}]

然后例如获取字段 value2 的值：

> proplists:get_value(value2, Proplist).
2