F# - 展平列表/范围

Question

我是 F# 新手，想知道如何展平列表。

本质上，我在数据库中存储了一条具有 min_age 和 max_age 范围的记录（为了简洁起见，这是一个虚构的示例 - 我并不支持！）。我的字段如下所示：

id， 成本， 储蓄， 最小年龄， max_age

我本质上有一个 F# 类，它充当与此表的一对一映射 - 即所有属性都精确映射到数据库字段。

我想做的就是拉平这个范围。因此，而不是包含这样的项目的列表：

saving_id = 1, cost = 100, savings = 20, min_age = 20, max_age = 26
saving_id = 2, cost = 110, savings = 10, min_age = 27, max_age = 31

我想要一个包含这样的项目的列表：

saving_id = 1, cost = 100, savings = 20, age = 20
saving_id = 1, cost = 100, savings = 20, age = 21
etc.
saving_id = 2, cost = 110, savings = 10, age = 27
saving_id = 2, cost = 110, savings = 10, age = 28
etc.

是否有任何内置机制可以以这种方式展平列表和/或有人知道如何实现这一点？ 预先感谢，

JP

Answer 1

您可能想使用 Seq.collect。它将序列连接在一起，因此在您的情况下，您可以在输入上映射一个函数，将单个年龄范围记录拆分为一系列年龄记录，并使用 Seq.collect 将它们粘合在一起。

例如：

type myRecord =
{ saving_id: int;
  cost: int;
  savings: int;
  min_age: int;
  max_age: int }

type resultRecord =
    { saving_id: int;
      cost: int;
      savings: int;
      age: int }

let records = 
    [ { saving_id = 1; cost = 100; savings = 20; min_age = 20; max_age = 26 }
      { saving_id = 2; cost = 110; savings = 10; min_age = 27; max_age = 31 } ]

let splitRecord (r:myRecord) =
    seq { for ageCounter in r.min_age .. r.max_age -> 
            { saving_id = r.saving_id;
              cost = r.cost;
              savings = r.savings;
              age = ageCounter }
    }

let ageRanges = records |> Seq.collect splitRecord

编辑：您还可以使用带有yield的序列生成器！

let thisAlsoWorks = 
    seq { for r in records do yield! splitRecord r }  

Answer 2

同意 cfern 的答案，但想知道这是否可以从使用另一个“内置”函数中受益。这是 splitRecord 函数的替代版本，它显示了展开序列的库调用。除了 Seq.unfold 的示例之外，这里没有任何收获。

let splitRecord (r:myRecord) = 
    Seq.unfold (fun curr_age ->
                    if curr_age <= r.max_age then
                        Some({  saving_id = r.saving_id; 
                                cost = r.cost; 
                                savings = r.savings; 
                                age = curr_age } ,
                                curr_age + 1) 
                    else None)
                r.min_age