在注释和文档字符串中使用较短的文本宽度

Question

来自强大的 PEP 8：

[P]请限制所有行最多 79 个字符。对于流动的长文本块（文档字符串或注释），建议将长度限制为 72 个字符。

在 Vim 中编辑 Python 代码时，我将 textwidth 设置为 79，当我达到字符限制时，Vim 会自动为我换行长行 Python 代码。但在注释和文档字符串中，我需要将文本换行为 72 个字符。

有没有办法让 Vim 在我处于注释或文档字符串时自动将 textwidth 设置为 72，并在完成后将其设置回来？

Answer 1

所以，我以前从未做过任何 Vim 脚本编写，但是基于 这个关于在 C 中执行类似的操作 和此提示用于检查您当前是否在评论中，我已经拼凑了一个解决方案。

默认情况下，这对普通行使用 PEP8 建议的 79 个字符的宽度，对注释使用 72 个字符的宽度，但您可以通过 letting g:python_normal_text_width 或 来覆盖它们>g:python_comment_text_width 变量，分别。 （就我个人而言，我将正常行换行为 78 个字符。）

将此宝贝放入您的 .vimrc 中，您应该可以开始了。稍后我可能会将其打包为插件。

function! GetPythonTextWidth()
    if !exists('g:python_normal_text_width')
        let normal_text_width = 79
    else
        let normal_text_width = g:python_normal_text_width
    endif

    if !exists('g:python_comment_text_width')
        let comment_text_width = 72
    else
        let comment_text_width = g:python_comment_text_width
    endif

    let cur_syntax = synIDattr(synIDtrans(synID(line("."), col("."), 0)), "name")
    if cur_syntax == "Comment"
        return comment_text_width
    elseif cur_syntax == "String"
        " Check to see if we're in a docstring
        let lnum = line(".")
        while lnum >= 1 && (synIDattr(synIDtrans(synID(lnum, col([lnum, "$"]) - 1, 0)), "name") == "String" || match(getline(lnum), '\v^\s*
) > -1)
            if match(getline(lnum), "\\('''\\|\"\"\"\\)") > -1
                " Assume that any longstring is a docstring
                return comment_text_width
            endif
            let lnum -= 1
        endwhile
    endif

    return normal_text_width
endfunction

augroup pep8
    au!
    autocmd CursorMoved,CursorMovedI * :if &ft == 'python' | :exe 'setlocal textwidth='.GetPythonTextWidth() | :endif
augroup END

Answer 2

接受的答案很棒！然而，它不支持我格式化/编辑注释的习惯：我进行编辑，然后使用 gqj 命令，本质上是“重新格式化当前行与下一行”。然后我点击了“。”对每一行重复该操作（命令本身将光标移动到下一行）。我不太了解 vim 脚本语言，因此有人可能可以在已接受的答案中添加对此的支持。与此同时，我所做的是映射功能键 (F6) 将文本宽度更改为 72，格式化该行，然后将文本宽度更改回 79。

nmap <F6> :set textwidth=72<CR>gqj:set textwidth=79<CR>

现在，当我在文档字符串中时，我只需进行编辑, (ESC)，然后重复按 F6，直到所有行的格式都正确。

我将地图命令和接受的应答脚本添加到我的 .vim/after/ftplugin/python.vim 中。