将函数名称绑定为宏内部的参数

Question

因此，我正在使用一个简单的文档字符串系统作为方案的热身，其想法是您可以执行以下操作：

(def-with-doc (foo a b)
  (desc     "Takes two parameters and sums them")
  (param 'a "First parameter")
  (param 'b "Second parameter")
  (return   "Sum of arguments")
  (+ a b)

这将变成：

(begin
  (begin
    (desc   'foo    "Takes two parameters and sums them")
    (param  'foo 'a "First parameter")
    (param  'foo 'b "Second parameter")
    (return 'foo    "Sum of arguments"))
  (begin
     (define (foo a b)
        (+ a b))))

我编写的宏：

(define doc-symbol-list '(param desc return))

(define-macro (def-with-doc arg-list #!rest body)
  ;; Loop over body, splitting into doc calls and everything else
  (let loop ((remaining body) (docs '()) (main '()))
    (if (null? remaining)
       ; Reverse accumulation order of docs and main
       ; And build re-ordered begin tree
       (let ((docs (cons 'begin (reverse docs)))
         (main (cons 'begin (reverse main))))
           (cons 'begin `(,docs ,`(define ,arg-list ,main))))

      ; Accumulate into docs list if expression is reserved
      ; Otherwise  into the body list
      (let ((sexp (car remaining)) (rest (cdr remaining)))
        (if (member (car sexp) doc-symbol-list)
        (loop rest (cons sexp docs) main)
        (loop rest  docs (cons sexp main)))))))

获取定义，移动参数/描述/return 调用包含在 begin 语句中的顶层并重建函数体，这样文档字符串调用仅在加载文件时执行一次，而不是每次调用函数时执行一次。我知道我可以手动将文档字符串内容放在顶层，但我正在尝试模拟 Python 文档字符串。

无论如何，我需要做的最后一个想法是将函数名称（上面的 foo ）绑定到文档字符串调用中，以便 (param 'a“第一个参数”) 变为 (param 'foo 'a“第一个参数”)以便知道每个调用关联的函数。这就是我遇到麻烦的地方，我所做的每一次尝试都未能达到我想要的效果。

Answer 1

我建议使用define-syntax，因为它很卫生，而且它的syntax-rules非常容易理解。 syntax-rules 采用模式到结果的格式；如果你能理解cond，你就能理解syntax-rules。

从之前和之后的片段来看，我认为这符合您的要求。

(define-syntax def-with-doc
    (syntax-rules ()
      ;; this pattern
      [(_ (func params ...)
          (tag attributes ...)
          ...
          code)
       ;; is converted into
       (begin
         (tag (quote func) attributes ...)
         ...
         (define (func params ...)
           code))]))

请原谅我的术语，因为我从未使用过文档字符串。
基本上，这与遵循函数 + params def、0 个或多个带有属性的标签以及代码语句的模式的任何内容相匹配。

然后，它只是重新安排一切。