Flash“这部电影中的脚本” - 由loadVars或setInterval引起的？

Question

这有点奇怪...

我有一个加载外部 SWF 的 Flash 文件。在那里，我使用 LoadVars 从服务器获取外部数据。当数据到达时，我使用 setInterval 来调用淡入内容的函数。

到目前为止，一切都很好。

但是，当我在所有数据到达之前切换菜单（也称为卸载一部电影以加载另一部电影）时，Flash 会挂起大约 15 秒，然后向我显示臭名昭著的消息“这部电影中的脚本正在减慢 Flash - 你想中止吗？”它？” （粗略翻译）。

我在 SWF 中附加了一个“onUnload”函数，这导致了主要问题，其中我使用clearInterval 来消除间隔并重新实例化 LoadVars 变量。

没有任何帮助...

有什么想法吗？

根据请求 - 这是导致问题的 SWF 的来源：

var myTimer = null;
var server_send:LoadVars = new LoadVars();

this.onUnload = function () {
    clearInterval(myTimer);
    server_send = new LoadVars();
    trace("stopping gewerbe");
};

var myself = scrollContent;

import JSON;    // external Class for parsing JSON

var sRes:LoadVars = new LoadVars();

function fadeIn(which){
    which._alpha += 3;

    if(which._alpha >= 100){
        clearInterval(myTimer);
    }
}

sRes.onLoad = function(success:Boolean){

    if (success){

        var o:Object = JSON.parse(sRes.res);
        var s:String = JSON.stringify(o); 

        //trace(sRes.res);

        var y = 0;

        for(item in o){

            actCol = 0;

            myself.attachMovie("row", "entry" + item, myself.getNextHighestDepth(), {_x: 0, _y:y});

            var tr = myself["entry" + item];

            tr.cTitle = o[item]["title"];
            tr.cBild = o[item]["image"];
            tr.cText = o[item]["text"];
            y += 65;

        }

        myTimer = setInterval(fadeIn, 0.1, myself);

        _root.myIntervals.push(myTimer);

    }
    else
    {
        trace("no connection...");
    }

}

myself._alpha = 0;

var vars = Array("id");
var values = Array("3");

server_send.load('void.txt');

for(var i=0;i<vars.length;i++)
{
    server_send[vars[i]] = escape(values[i]);
}

server_send.sendAndLoad(_global.server, sRes, "POST");

stop();

Answer 1

更新

首先，我建议您放弃使用 setInterval，它们特别有问题。而是使用 Timer 类，它的管理和使用要简单得多。

不过，sRes.onLoad 函数内的setInterval 可能是您的问题。间隔应以毫秒为单位，因此您的 0.1 可能应为 100（1/10 秒），并且 fadeIn 和 unLoad 中的 clearInterval 调用> 可能有 myInterval 超出范围，请使用 trace 检查它们以确保它们按预期清除。

代码

好吧，我已经重新排序了代码以使其更具可读性......但是，它的形状仍然很糟糕。我正在标记需要与您进一步讨论的内容...（请参阅下面代码中的其他注释。）

stop();

// Moved import to the top.
import JSON;

// Grouping var declarations.
var myself = scrollContent;
myself._alpha = 0;

var values = Array("3");
var myTimer = null;
var sRes:LoadVars = new LoadVars();
var server_send:LoadVars = new LoadVars();
var vars = Array("id");    

// why are we looping through an array of one value?
for(var i=0; i<vars.length; i++)
{
    server_send[vars[i]] = escape(values[i]);
}

server_send.load('void.txt'); // what is this for?

server_send.sendAndLoad(_global.server, sRes, "POST"); // where do we define _global.server

this.onUnload = function () {
    clearInterval(myTimer); // is myTimer in scope here?
    server_send = new LoadVars();
    trace("stopping gewerbe");
};    

function fadeIn(which){
    which._alpha += 3;
    if(which._alpha >= 100){
        clearInterval(myTimer); // is myTimer in scope here?
    }
}

sRes.onLoad = function(success:Boolean)
{
    if (success)
    {
        var o:Object = JSON.parse(sRes.res);
        var s:String = JSON.stringify(o); 
        var y = 0;

        for(item in o)
        {
            actCol = 0;
            myself.attachMovie("row", "entry" + item, myself.getNextHighestDepth(), {_x: 0, _y:y});
            var tr = myself["entry" + item];
            tr.cTitle = o[item]["title"];
            tr.cBild = o[item]["image"];
            tr.cText = o[item]["text"];
            y += 65;
        }

        myTimer = setInterval(fadeIn, 0.1, myself); // setInterval uses milliseconds 0.1 is almost certainly the problem. 
                                                    // if you want 1/10th of a second, specify 100 as the interval.
        _root.myIntervals.push(myTimer); // We never see _root.myIntervals again, what's this for? 
                                         // The fadeIn and unLoad methods could use this to 
                                         // guarantee that they clear the right interval.
    }
    else
    {
        trace("no connection...");
    }
}

Answer 2

感谢您的帮助 - 似乎我发现了这个怪癖...

即使电影被卸载，sendAndLoad-response 仍然被调用，似乎导致了循环。

我所做的是：

在脚本顶部添加一个名为“doParse”的变量并将其设置为 true

var doParse = true;

然后在卸载函数中，我将此 var 设置为 false：

this.onUnload = function () {
doParse = false;
...
}

如果数据到达时被调用，我添加了这个：

if(success && doParse == true){
...
}

这有帮助，消息消失了。