如何创建内部（私有）Moose 对象变量（属性）？

Question

我希望某些属性（也许在这种情况下这是错误的术语）是私有的，也就是说，仅在对象内部使用 - 不能从外部读取或写入。

例如，考虑一些内部变量，它计算一组方法中任何一个方法被调用的次数。

我应该在哪里以及如何定义这样的变量？

Answer 1

Moose::Manual::Attributes 显示了以下创建私有属性的方法：

has '_genetic_code' => (
   is       => 'ro',
   lazy     => 1,
   builder  => '_build_genetic_code',
   init_arg => undef,
);

设置 init_arg 意味着该属性不能在构造函数中设置。如果您需要更新它，请将其设为 rw 或添加 writer。

/I3az/

Answer 2

你可以尝试这样的事情：

has 'call_counter' => (
    is     => 'ro',
    writer => '_set_call_counter',
);

is =>; 'ro' 使属性只读。 Moose 生成吸气剂。您的方法将使用 getter 来递增值，如下所示：

sub called {
    my $self = shift;
    $self->_set_call_counter( $self->call_counter + 1 );
    ...
}

writer =>; '_set_call_counter' 生成一个名为 _set_call_counter 的 setter。 Moose 不支持真正的私有属性。从技术上讲，外部代码可以调用_set_call_counter。但按照惯例，应用程序不会调用以下划线开头的方法。

Answer 3

我认为您想要 MooseX::Privacy。

perldoc 告诉您您应该需要的一切 - 它为您的属性添加了一个新特征，允许您将它们声明为私有或受保护：

has config => (
    is     => 'rw',
    isa    => 'Some::Config',
    traits => [qw/Private/],
);

Answer 4

我一直无法找到一种方法使 Moose 属性完全私有。每当我使用 has 'name' =>; (...); 要创建一个属性，它总是至少暴露于读取。对于我想要真正私有的项目，我在 Moose 包中使用标准的“我的”变量。作为一个快速示例，请使用以下模块“CountingObject.pm”。

package CountingObject;

use Moose;

my $cntr = 0;

sub add_one { $cntr++; }

sub get_count { return $cntr; }

1;

使用该模块的脚本无法直接访问 $cntr 变量。他们必须使用“add_one”和“get_count”方法作为与外界的接口。例如：

#!/usr/bin/perl 

### Call and create
use CountingObject;
my $co = CountingObject->new();

### This works: prints 0
printf( "%s\n", $co->get_count() );

### This works to update $cntr through the method
for (1..10) { $co->add_one(); }

### This works: prints 10
printf( "%s\n", $co->get_count() );

### Direct access won't work. These would fail:
# say $cntr;
# say $co->cntr;

我是 Moose 的新手，但据我所知，这种方法提供了完全私有的变量。

Answer 5

Alan W. Smith 提供了一个带有词法变量的私有类变量，但它由类中的所有对象共享。尝试在示例脚本的末尾添加一个新对象：

my $c1 = CountingObject->new();
printf( "%s\n", $c1->get_count() );
#  also shows a count of 10, same as $co

使用 MooseX:Privacy 是一个很好的答案，但如果你不能，你可以借用从内到外对象阵营的技巧：

package CountingObject;

use Moose;

my %cntr;

sub BUILD { my $self = shift; $cntr{$self} = 0 }

sub add_one { my $self = shift; $cntr{$self}++; }

sub get_count { my $self = shift; return $cntr{$self}; }

1;

这样，每个对象的计数器都被存储作为词法哈希中的条目。上面的内容可以更简洁地实现：

package CountingObject;

use Moose;

my %cntr;

sub add_one { $cntr{$_[0]}++ }

sub get_count { return $cntr{$_[0]}||0 }

1;