如何灵活向Moose对象添加数据？

Question

我正在为驼鹿对象编写一个模块。我想允许使用此对象的用户（或我自己......）根据他/她的需要动态添加一些字段。我无法先验地定义这些字段，因为我根本不知道它们是什么。

我目前只是添加了一个名为 extra 的 hashref 类型字段，该字段设置为 rw，因此用户可以简单地将内容放入该哈希中：

# $obj is a ref to my Moose object    
$obj->extra()->{new_thingie}="abc123"; # adds some arbitrary stuff to the object
say $obj->extra()->{new_thingie};

这有效。但是……这是常见做法吗？还有其他（可能更优雅的）想法吗？

请注意，我不想创建另一个模块来扩展这个模块，这实际上只是为了我想添加的即时内容。

Answer 1

我可能会通过本机特征来做到这一点：

has custom_fields => (
    traits     => [qw( Hash )],
    isa        => 'HashRef',
    builder    => '_build_custom_fields',
    handles    => {
        custom_field         => 'accessor',
        has_custom_field     => 'exists',
        custom_fields        => 'keys',
        has_custom_fields    => 'count',
        delete_custom_field  => 'delete',
    },
);

sub _build_custom_fields { {} }

在一个对象上，您可以像下面这样使用它：

my $val = $obj->custom_field('foo');           # get field value
$obj->custom_field('foo', 23);                 # set field to value

$obj->has_custom_field('foo');                 # does a specific field exist?
$obj->has_custom_fields;                       # are there any fields?

my @names = $obj->custom_fields;               # what fields are there?
my $value = $obj->delete_custom_field('foo');  # remove field value

此类内容的常见用例是将可选的可自省数据添加到异常和消息类。

Answer 2

如果您还没有使类不可变（有一个 性能损失（除了我担心动态更改类定义之外），您应该能够通过获取对象的元类来做到这一点（使用 $meta = $object ->meta) 并使用 add_attribute 方法="noreferrer">类::MOP::类。

#!/usr/bin/perl

package My::Class;

use Moose;
use namespace::autoclean;

package main;

my $x = My::Class->new;
my $meta = $x->meta;
$meta->add_attribute(
    foo => (
        accessor => 'foo',
    )
);

$x->foo(42);

print $x->foo, "\n";

my $y = My::Class->new({ foo => 5 });
print $y->foo, "\n";

输出：

42
5

Answer 3

如果您想向对象而不是整个类添加方法，请查看类似 MooseX::SingletonMethod。

例如

use 5.012;
use warnings;

{
    package Foo;
    use MooseX::SingletonMethod;
    sub bar { 'bar' }     # method available to all objects
}

my $foo = Foo->new;

$foo->add_singleton_method( baz => sub { 'baz!' } );

$foo->baz;     # => baz!

，上面的方法 baz 仅添加到对象 $foo 中，而不添加到类 Foo 中。

嗯...我想知道我是否可以实现 MooseX::SingletonAttribute？

之前的一些 SO 答案使用 MooseX::SingletonMethod：

• 如何替换Moose 对象在运行时的方法？
• 我如何创建一个新的 Moose 类并在运行时实例化该类的对象？

而且这篇博客文章可能有用并且/或兴趣：简单匿名对象

/I3az/

Answer 4

即使在运行时修改类不是一个好的做法，您也可以简单地使元类可变，添加属性并再次使类不可变：

 $ref->meta->make_mutable ;
 $ref->meta->add_attribute($attr_name,%cfg) ;
 $ref->meta->make_immmutable ;