如何有条件地使用 Perl 中的模块？

Question

我想在 Perl 中做这样的事情：

$Module1="ReportHashFile1"; # ReportHashFile1.pm
$Module2="ReportHashFile2"; # ReportHashFile2.pm

if(Condition1)
{
  use $Module1;
}
elsif(Condition2)
{
  use $Module2;
}

ReportHashFile*.pm 包含一个包 ReportHashFile* 。

另外如何根据动态模块名称引用模块内部的数组？

@Array= @$Module1::Array_inside_module;

无论如何我可以实现这个目标吗？某种编译器指令？

Answer 1

您可能会发现 if 模块对此很有用。

否则，基本思想是使用在运行时发生的 require，而不是在编译时发生的 use。请注意，'

BEGIN {
    my $module = $condition ? $Module1 : $Module2;
    my $file = $module;
    $file =~ s[::][/]g;
    $file .= '.pm';
    require $file;
    $module->import;
}

至于寻址全局变量，如果您只是导出变量或将其返回给调用者的函数，则可能会更容易，您可以通过其非限定名称来使用它。否则，也可以使用方法并将其调用为 $Module->method_name。

或者，您可以使用 perlref 中记录的符号引用。然而，这通常是一种代码味道。

my @array = do {
    no strict 'refs';
    @{ ${ "${Module}::Array_inside_module" } };
};

Answer 2

除非执行速度很重要，否则可以使用字符串 eval：

if (Condition1) {
    eval "use $Module1"; die $@ if $@;
}
elsif (Condition2) {
    eval "use $Module2"; die $@ if $@;
}

Answer 3

人们已经告诉过您如何使用 Perl 原语加载模块。还有Module::Load::Conditional。

如果您希望访问同名的数组，无论您加载哪个模块，请考虑为此创建一个方法，以便您可以跳过符号引用内容。为每个模块提供一个同名的方法：

package ReportHashFileFoo;
our @some_package_variable;
sub get_array { \@some_package_variable }

然后，当您加载该模块时：

if( ... some condition ... ) {
    eval "use $module" or croak ...;
    my $array_ref = $module->get_array;
    }

2023 update 最近我一直在 state 中使用 require > 表达式，因为这只在范围内发生一次：

use v5.10;

if( ... some condition ... ) {
    state $rc =  require $module;
    my $array_ref = $module->get_array;
    }

我不知道你真正在做什么 (XY 问题），但可能有更好的设计。当事情看起来像这样棘手时，通常是因为您忽略了更好的解决方法。

Answer 4

也许有帮助...

调试的小例子。

sub DEBUG () {1};               # It's the condition (may be a debuglevel...)

use if DEBUG, Data::Dumper;     # Conditionally load

my $testvar = "foo";
print "Testing: $testvar\n" if     DEBUG;
print "No testing\n"        unless DEBUG;

print Dumper \$testvar if DEBUG;  # "Dumper" only available if "DEBUG" returns "true".

使用 sub DEBUG () {1}; 输出

Testing: foo
$VAR1 = \'foo';

sub DEBUG () {0};

No testing

qv
perldoc.perl.org/if