如何在 Perl 中仅打开尚未打开的文件？

Question

如果我有一个打开文件的子例程，确保它仅在第一次调用子例程时打开它的最佳方法是什么？我有这个，但不确定它是否是最佳实践：

{
my $count = 0;
sub log_msg {
    my ($msg,$name) = @_;

    if ($count == 0) {
        my $log_file_name = "/tmp/" . $name;
        open my $log_fh,">",$log_file_name or  croak "couldn't open $log_file_name : $!";
        print $log_fh "$timestamp: created and opened $log_file_name\n";
    }
    $count++;
    }
}

Answer 1

好吧，对于初学者来说，$count++ 应该放在 if 语句中，并且可以简单地更改为 $count=1。您可能还想将 $count 重命名为 $file_opened_flag 或更有意义的名称。除此之外，我认为这没有什么问题。

Answer 2

我不认为使用本身有什么问题，但如果真的只有 1 个文件要跟踪，为什么不将 $log_fh 保留在闭包中并使用 if(!$log_fh ->opened()) 而不是计数变量？

Answer 3

听起来像是使用状态变量的一个很好的理由。将文件句柄存储在持久哈希中。

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;

sub log_msg {
  state %fh;
  my ($msg, $name) = @_;

  unless ($fh{$name}) {
    warn "Opening $name\n";
    open $fh{$name}, '>', $name or die $!;
    print {$fh{$name}} scalar localtime, " Opened file\n";
  }

  print {$fh{$name}} $msg, "\n";
}

log_msg('Message1', 'first.log');
log_msg('Message2', 'first.log');
log_msg('MessageA', 'second.log');
log_msg('MessageB', 'second.log');

请注意打印调用中文件句柄周围的额外大括号。这是因为 print 对于可以用作其文件句柄参数的内容有点挑剔。

Answer 4

最好的方法是使用 Log::Log4perl 这样你就不必考虑有了它，您就可以专注于真正的任务。

除此之外，您还可以使用我们在有效 Perl 编程中介绍的一些文件和文件句柄技巧。幸运的是，这也是我们的出版商赠送的免费章节。

简而言之，您不想在日常日志记录中考虑这一点。这是混乱的代码。相反，创建一个返回缓存的文件句柄或打开它的方法（这很像您用来 ping 数据库句柄并在需要时重新连接的方法）：

 sub log_msg {
      my( $self, $msg, $name ) = @_;

      print { $self->get_fh_by_name( $name ) } $msg;
      }

 BEGIN { # to define variables before the subroutine
 my %log_fhs;
 sub get_fh_by_name {
     my( $self, $name ) = @_;

     return $log_fhs{$name} if defined $log_fhs{$name};

     open my $log_fh, catdir( $base_dir, $name ) or croak "...";
     print $logfh ...

     $log_fhs{$name} = $log_fh;
     }
 }