如何在Delphi中模拟TFrame上的OnDestroy事件？

Question

如何在 Delphi 中模拟 TFrame 的 OnDestroy 事件？

---

我天真地将构造函数和析构函数添加到我的框架中，认为这就是TForm所做的：

TframeEditCustomer = class(TFrame)
...
public
   constructor Create(AOwner: TComponent); override;
   destructor Destroy; override;
   ...
end;

constructor TframeEditCustomer.Create(AOwner: TComponent)
begin
    inherited Create(AOwner);
    
    //allocate stuff
end;

destructor TframeEditCustomer.Destroy;
begin
   //cleanup stuff

   inherited Destroy;
end;

问题是，到我的析构函数时运行时，框架上的控件已被破坏并且不再有效。

其原因在于包含表单的析构函数，它使用该析构函数来触发 OnDestroy 事件：

destructor TCustomForm.Destroy;
begin
   ...
   if OldCreateOrder then DoDestroy; //-->fires Form's OnDestroy event; while controls are still valid
   ...
   if HandleAllocated then DestroyWindowHandle; //-->destroys all controls on the form, and child frames
   ...
   inherited Destroy; //--> calls destructor of my frame
   ...
end;

当表单的析构函数运行时，将调用我的框架对象的析构函数。问题是为时已晚。表单调用DestroyWindowHandle，它要求Windows销毁表单的窗口句柄。这会递归地销毁所有子窗口 - 包括我框架上的子窗口。

因此，当我的框架的析构函数运行时，我尝试访问不再处于有效状态的控件。

---

如何在 Delphi 中模拟 TFrame 的 OnDestroy 事件？

Answer 1

您需要添加 WM_DESTROY 处理程序并检查 ComponentState 中的 csDestroying，以便仅在实际销毁时捕获它，而不是在重新创建句柄时捕获它。

type
  TCpFrame = class(TFrame)
  private
    FOnDestroy: TNotifyEvent;
    procedure WMDestroy(var Msg: TWMDestroy); message WM_DESTROY;
  published
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

procedure TCpFrame.WMDestroy(var Msg: TWMDestroy);
begin
  if (csDestroying in ComponentState) and Assigned(FOnDestroy) then
    FOnDestroy(Self);
  inherited; 
end;

仅当框架的窗口句柄已实际创建时，这才有效。没有其他好的挂钩点，因此如果您想确保它始终被调用，您需要在 WMDestroy 中设置一个标志，并在未命中时回退到在析构函数中调用它。

窗口句柄本身在 WM_NCDESTROY 中全部清除，该窗口句柄在所有后代 WM_DESTROY 消息返回后调用，因此此时窗体及其所有子句柄应该仍然有效（忽略在窗体 OnDestroy 中释放的任何句柄） 。

Answer 2

听起来更像是 OnClose 而不是 OnDestroy。

无论如何，我只是从基础祖先继承了所有框架和表单，并且表单的 onclose 调用了组件层次结构中的所有框架。

Answer 3

（这只是一个想法，但我现在没有时间构建概念证明，但我仍然会分享它：）

如果是 Windows 句柄问题，您应该检查是否“能够附加一个 Windows”事件回调指针，当框架的 Windows 句柄不再存在时，该指针将被调用。也许使用像 RegisterWaitForSingleObject 这样的函数

Answer 4

另一种选择是覆盖 AfterConstruction 和 BeforeDestruction

如下所示：

  TMyFrame = class(TFrame)
  private
    FOnCreate: TNotifyEvent;
    FOnDestroy: TNotifyEvent;
  protected
    procedure DoCreate; virtual;
    procedure DoDestroy; virtual;
  public
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;
    property OnCreate: TNotifyEvent read FOnCreate write FOnCreate;
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

  implementation

  procedure TMyFrame.AfterConstruction;
  begin
    inherited;
    DoCreate;
  end;

  procedure TMyFrame.BeforeDestruction;
  begin
    inherited;
    DoDestroy;
  end;

  procedure TMyFrame.DoCreate;
  begin
    if Assigned(FOnCreate) then
      FOnCreate(Self);
  end;

  procedure TMyFrame.DoDestroy;
  begin
    if Assigned(FOnDestroy) then
      FOnDestroy(Self);
  end;