xslt 在不同的节点上？

Question

我有以下架构：

<parent>
  <child id="1" name="Child 1 Version 1" />
</parent>
<parent>
  <child id="2" name="Child 2 Version 1" />
</parent>
<parent>
  <child id="1" name="Child 1 Version 2" />
</parent>

我只想处理每个 id 的最后一个节点。以下是我根据一些阅读尝试过的方法：

  <xsl:for-each select="//parent/child">
    <xsl:sort select="@id"/>
    <xsl:if test="not(@id=following-sibling::*/@id)">
      <xsl:element name="child">
        <xsl:value-of select="@name"/>
      </xsl:element>
    </xsl:if>
  </xsl:for-each>

但它似乎不起作用。我的输出仍然包含所有三个元素。关于我可以采取哪些措施来纠正我的问题有什么想法吗？

Answer 1

我只想处理最后一个
每个 id 的节点。以下是我所拥有的
根据一些阅读尝试：

  <xsl:for-each select="//parent/child"> 
    <xsl:sort select="@id"/> 
    <xsl:if test="not(@id=following-sibling::*/@id)"> 
      <xsl:element name="child"> 
        <xsl:value-of select="@name"/> 
      </xsl:element> 
    </xsl:if> 
  </xsl:for-each> 

但是好像不行。我的
输出仍然包含所有三个
元素。关于我能做什么的任何想法
纠正我的问题？

此代码的问题是，即使节点位于已排序的节点集中，它们的 following-sibling 仍然是文档中的节点。

为了使此代码正常工作，首先创建一个全新的文档，其中节点以所需的方式排序，然后（在 XSLT 1.0 中，需要使用 xxx:node-set() 生成的 RTF 上的扩展名，使其成为普通的 XML 文档）在此文档上，节点根据需要具有其同级节点。

解决方案：

此转换提供了一种可能的 XSLT 1.0 解决方案，不需要使用扩展函数：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kchildById" match="child" use="@id"/>

 <xsl:template match="/*">
  <t>
    <xsl:apply-templates select=
    "*/child[generate-id()
            =
             generate-id(key('kchildById',
                             @id)[last()]
                         )
            ]
    "/>
  </t>
 </xsl:template>

 <xsl:template match="child">
  <child>
   <xsl:value-of select="@name"/>
  </child>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的 XML 片段时（包装在顶部元素中以变得很好） -形成的 XML 文档并为 id="2" 添加第二个版本）：

<t>
    <parent>
        <child id="1" name="Child 1 Version 1" />
    </parent>
    <parent>
        <child id="2" name="Child 2 Version 1" />
    </parent>
    <parent>
        <child id="1" name="Child 1 Version 2" />
    </parent>
    <parent>
        <child id="2" name="Child 2 Version 2" />
    </parent>
</t>

产生想要的结果：

<t>
   <child>Child 1 Version 2</child>
   <child>Child 2 Version 2</child>
</t>

请注意：使用慕尼黑分组方法。

Answer 2

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kParentByChildId" match="parent" use="child/@id"/>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="parent[count(.|key('kParentByChildId',
                                            child/@id)[last()]) != 1]"/>
</xsl:stylesheet>

输出：

<root>
    <parent>
        <child id="2" name="Child 2 Version 1"></child>
    </parent>
    <parent>
        <child id="1" name="Child 1 Version 2"></child>
    </parent>
</root>

注释。按@id分组，选择组中的最后一个。

编辑：以防万一这令人困惑。上面的样式表意味着：复制除那些没有最后一个@id同类的子之外的所有内容。因此，它不是选择组中的最后一个，而是作为反向逻辑，条带化不是组中的最后一个。

第二。为什么你的不工作？嗯，因为following-sibling 轴。您找到第一个同类的方法来自于旧时代，当时几乎没有处理器实现密钥。现在那些日子已经一去不复返了。

因此，这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:template match="t">
        <xsl:for-each select="parent/child">
            <xsl:sort select="@id"/>
            <xsl:if test="not(@id=following::child/@id)">
                <xsl:element name="child">
                    <xsl:value-of select="@name"/>
                </xsl:element>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

输出：

<child>Child 1 Version 2</child>
<child>Child 2 Version 1</child>

注意：跟随轴，因为子元素没有兄弟元素。