商务类中属性的使用与 getter/setter 的比较

Question

在处理业务类（例如典型的 Customer 和 Employee 类）时，仅使用 getter 和 setter 还是使用属性更好？

我正在将java书籍中的一些OO示例翻译为Delphi（用于自学），在这些示例中总是有GetName()和SetName()，不使用属性。

现在，我可以看到，如果我创建一个具有已发布属性的组件，我就有充分的理由使用属性，但在普通类中，哪种方法更好？使用 getter 和 setter（强调我们正在读取/写入属性的事实）或使用属性（乍一看可能与无参数方法混淆）的代码是否更具可读性？

Answer 1

哇。属性的含义远不止“它们只是 getter 和 setter 方法的包装”。

属性是一种优雅但功能强大的方法，可以提供对类字段的受控访问。

访问字段

正如已经说过的，您可以直接访问类字段。这确实非常好，并且使代码更加清晰。这也是实现类的可行第一个版本的非常好的方法。

TMyClass = class
private
  FValue: String;
public
  property Value: String read FValue write FValue;
end; 

稍后，您可以重新设计类以使用方法验证和操作字段访问。公共接口仍然相同。

TMyClass = class
private
  FValue: String;
  procedure SetValue(AValue: String);
public
  property Value: String read FValue write SetValue;
end; 

procedure TMyClass.SetValue(AValue: String);
begin
  if AValue = '' 
  then FValue := 'No value!'
  else FValue := AValue;
end;

控制访问

属性使您可以轻松概览只读/只写字段。例如，只读/不可变类：

TClient = class
private
  FName: String;
  FSite: String;
  FMail: String;
public
  constructor Create(AName, ASite, AMail: String);
  property Name: String read FName;
  property Site: String read FSite;
  property Mail: String read FMail;
end; 

多态性

TClient = class
private
  FName: String;
protected
  function GetName: String; virtual; abstract;
public
  property Name: String read GetName write FName;
end; 

TImportantClient = class(TClient)
protected
  function GetName: String; override;
end; 

TArgumentativeClient = class(TClient)
protected
  function GetName: String; override; 
end; 

function TImportantClient.GetName: String; 
begin
  Result := '+++ ' + FName;
end; 

function TArgumentativeClient.GetName: String; 
begin
  Result := ':-( ' + FName;
end; 

{----- ----- ----- ----- -----}
var
  ClientA,
  ClientB: TClient;
begin
  ClientA := TImportantClient.Create;
  ClientB := TArgumentativeClient.Create;

  ClientA.Name := 'Mr. Nice';
  ClientB.Name := 'Mr. Dumbhead';

  ShowMessage(ClientA.Name);
  ShowMessage(ClientB.Name);
end;
{----- ----- ----- ----- -----}

默认属性

在您的类中，您可以定义默认类字段，这意味着您可以直接访问该字段而无需指定属性名称。

A := MyStringList[i]:
MyStringList[i] := B;

{ instead of }

A := MyStringList.Strings[i];
MyStringList.Strings[i] := B;

{ or }

A := MyStringList.GetString(i);
MyStringList.SetString(i, B);

Index

使用 Index 关键字，Delphi 会将一个常量值作为参数传递给 getter/setter 方法。

TMyRect = class
private
  FValues: Array[0..3] of Integer;
  function GetProperty(Index: Integer): Integer;
public
  property Top    : Integer  Index 0  read GetProperty;
  property Left   : Integer  Index 1  read GetProperty;
  property Width  : Integer  Index 2  read GetProperty;
  property Height : Integer  Index 3  read GetProperty;
end;


function TMyRect.GetProperty(Index: Integer): Integer;
begin
  Result := FValues[Index];
end; 

一些资源

仍然有一些主题需要涵盖（实现接口、存储值、RTTI/设计时属性等），但是这篇文章开始变得有点长......

更多内容可以在这些站点阅读：

• http://www.delphibasics.co.uk
• http://delphi.about.com
• http://mc-computing.com

Answer 2

不。 getter 和 setter 仅在 Java 中存在，因为它没有属性。它使得使用属性的代码更加简洁。然后，如果您需要 getter 或 setter，您可以将其构建到属性中，但不必在访问代码中添加一堆函数调用。

Answer 3

属性是Delphi的一大优势。我自己已经做过相当多的 Java 和 Delphi 工作，并且肯定会选择 Properties。实际上，这两种方法最终都会做同样的事情，唯一的区别是属性看起来比 getter/setter 整洁得多。

我建议你去购买房产，并充分利用它们！

Answer 4

这确实是一个品味和用途的问题。

对于像 pascal 这样的程序员来说，如果你正在读取或写入一个值，这是非常清楚的，所以我认为如果你不以类似 java 的方式使用 getter 和 setter，即在每一个句子中编写 GetXXX 或 SetXXX，那么代码的可读性会更高你的程序。

对于我来说，我假设对于大多数 pascal 程序员来说，如果您只输入正在读取/写入的属性的名称，则代码更具可读性，并且我们都知道将调用 Getter 或 Setter 方法（如果需要） 。

另外，我认为 delphi 属性模型的一个巨大好处（和优雅）是，您可以直接从字段获取/设置属性值 只需一行代码即可获得大量 Get/Set 方法，其中值是从字段中分配或读取完全是浪费精力/时间。