“继续” （到下一次迭代）在 VBScript 上

Question

我和一位同事试图找出一种方法，在 VBScript“For/Next”循环中执行相当于“继续”语句的操作。

我们到处寻找，发现人们无法在 VBScript 中做到这一点而不需要令人讨厌的嵌套，这对我们来说不是一个选择，因为它是一个相当大的循环。

我们提出了这个想法。它会像“继续（到下一次迭代）”一样工作吗？有没有人有更好的解决方法或改进建议？

For i=1 to N
  For workaroundloop = 1 to 1
    [Code]
    If Condition1 Then
      Exit For
    End If
  
    [MoreCode]
    If Condition2 Then
      Exit For
    End If
  
    [MoreCode]
    If Condition2 Then
      Exit For
    End If
  
    [...]

  Next
Next

Answer 1

您的建议可行，但使用 Do 循环可能更具可读性。

这实际上是 C 语言中的一个习惯用法 - 如果您想尽早摆脱构造，您可以使用 do { } while (0) 循环和break语句，而不是使用 goto 。

Dim i

For i = 0 To 10
    Do
        If i = 4 Then Exit Do
        WScript.Echo i
    Loop While False
Next

正如美眉建议的那样，如果去掉额外的缩进级别，看起来会好一些。

Dim i

For i = 0 To 10: Do
    If i = 4 Then Exit Do
    WScript.Echo i
Loop While False: Next

Answer 2

我决定使用布尔变量来跟踪 for 循环是否应该处理其指令或跳到下一次迭代：

Dim continue

For Each item In collection
    continue = True

    If condition1 Then continue = False End If

    If continue Then
        'Do work
    End If
Next

我发现嵌套循环解决方案在可读性方面有些令人困惑。此方法也有其自身的缺陷，因为循环在遇到 continue 后不会立即跳到下一次迭代。稍后的条件可能会反转继续的状态。它在初始循环中还有一个辅助构造，并且需要声明一个额外的变量。

哦，VBScript...叹息。

另外，如果您想使用已接受的答案（可读性还不错），您可以将其与使用 : 结合起来，将两个循环合并为一个循环：

Dim i

For i = 0 To 10 : Do
    If i = 4 Then Exit Do
    WScript.Echo i
Loop While False : Next

我发现它对于消除额外的缩进很有用。

Answer 3

一种选择是将循环中的所有代码放入 Sub 内，然后当您想要“继续”时从该 Sub 返回。

并不完美，但我认为额外的循环不会那么令人困惑。

Answer 4

我过去经常使用 Do、Loop，但我已经开始使用可以退出的 Sub 或 Function。对我来说它看起来更干净。如果您需要的任何变量不是全局的，您还需要将它们传递给 Sub。

For i=1 to N
 DoWork i
Next

Sub DoWork(i)
    [Code]
    If Condition1 Then
      Exit Sub
    End If

    [MoreCode]
    If Condition2 Then
      Exit Sub
    End If

    [MoreCode]
    If Condition2 Then
      Exit Sub
    End If

    [...]
End Sub

Answer 5

我们可以使用单独的函数来执行 continue 语句工作。假设您有以下问题：

for i=1 to 10

if(condition) then   'for loop body'
contionue
End If

Next

这里我们将使用 for 循环体的函数调用：

for i=1 to 10
Call loopbody()
next

function loopbody()

if(condition) then   'for loop body'
Exit Function
End If

End Function

循环将继续 for 函数退出语句......

Answer 6

我一直使用 Do While 循环。这适用于两种 For 类型循环。

For iIndex = 0 to 100
  Do
    If bCondition then Exit Do
    ...
  Loop While False
Next 

恕我直言，这看起来很干净。
我刚刚看到了 Crush 的回答，在底部。抱歉重复的答案。

Answer 7

将迭代实现为递归函数。

Function Iterate( i , N )
  If i == N Then
      Exit Function
  End If
  [Code]
  If Condition1 Then
     Call Iterate( i+1, N );
     Exit Function
  End If

  [Code]
  If Condition2 Then
     Call Iterate( i+1, N );
     Exit Function
  End If
  Call Iterate( i+1, N );
End Function

首先调用 Iterate( 1, N )

Answer 8

尝试使用 While/Wend 和 Do While / Loop 语句...

i = 1
While i < N + 1
Do While true
    [Code]
    If Condition1 Then
       Exit Do
    End If

    [MoreCode]
    If Condition2 Then
       Exit Do
    End If

    [...]

    Exit Do
Loop
Wend

Answer 9

我认为您打算在 if 语句下包含所有逻辑。基本上：

' PRINTS EVERYTHING EXCEPT 4
For i = 0 To 10
  ' you want to say
  ' If i = 4 CONTINUE but VBScript has no continue
  If i <> 4 Then ' just invert the logic
    WSH.Echo( i )
  End If
Next

这可能会使代码更长一些，但有些人不这样做无论如何，我不喜欢break或continue。