使用 xml 作为 xsl 变量

Question

我必须使用不同语言的两个文本块创建稍微动态的 pdf（两个变量）。

两个块中的大部分文本都是静态的，

我在想是否可以创建一个模板来为布局创建 xsl-fo。然后创建两个包含自定义 xml 的变量。就像：

<xsl:variable name="TEXT_CONTENT_ENG" >
  <STATIC_TEXT> 
   <LABEL>Hello</LABEL>
   <REQUEST>Please pay your bill before </REQUEST>
  </STATIC_TEXT>
</xsl:variable>

最后我可以使用这些变量应用创建的模板两次。

xsl 似乎使用给定变量进行验证，但我无法将模板应用于该 xml。尝试过，文档（$TEXT_CONTENT_ENG）也不起作用。

这是否可能以及如何做到？

Answer 1

两个块中的大部分文本都是
静态

如果这是真的，那么正确的 XSLT 方式是内联数据。来自 http://www.w3.org/TR/xslt#stylesheet-element

此外，xsl:stylesheet
元素可以包含任何不包含的元素
来自 XSLT 命名空间，前提是
元素的扩展名称有一个
非空命名空间 URI。存在感
此类顶级元素不得
更改 XSLT 元素的行为
以及在此定义的函数
文档;例如，它不会是
允许这样的顶级元素
指定 xsl:apply-templates
是使用不同的规则来解决
冲突。因此，XSLT 处理器是
总是可以忽略这样的顶级
元素，并且必须忽略顶级
如果元素没有给出错误
无法识别名称空间 URI。
这些元素可以提供，
例如，

• 扩展元素或扩展函数使用的信息（请参阅
  [14 个扩展]),

• 有关如何处理结果树的信息，

• 有关如何获取源树的信息，

• 有关样式表的元数据，

• 样式表的结构化文档。

<stylesheet version="1.0" xmlns="http://www.w3.org/1999/XSL/Transform">
    <variable name="vRTF">
        <STATIC_TEXT xmlns="">
            <LABEL>Hello</LABEL>
            <REQUEST>Please pay your bill before </REQUEST>
        </STATIC_TEXT>
    </variable>
    <template match="/">
        <apply-templates
              select="document('')/*/xsl:variable[@name='vRTF']/node()"
              xmlns:xsl="http://www.w3.org/1999/XSL/Transform"/>
    </template>
    <template match="@*|node()">
        <copy>
            <apply-templates select="@* | node()"/>
        </copy>
    </template>
</stylesheet>

输出：

<STATIC_TEXT>
    <LABEL>Hello</LABEL>
    <REQUEST>Please pay your bill before </REQUEST>
</STATIC_TEXT>

注意：在 XML 1.0 中，您只能重置默认命名空间。

Answer 2

Alejandro 的答案总体上是正确的，但是命名空间的非常规使用有点令人困惑，而且他将数据包装在不必要的 xsl:variable 元素中，这也有点令人困惑。

只要将元素放入其自己的命名空间中，就可以使其成为 xsl:stylesheet 元素的子元素。然后，您可以使用 document('') 访问它，它返回当前的 XSLT 文档：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:in="urn:inline-data"
    exclude-result-prefixes="in"
>

   <in:TEXT_CONTENT_ENG>
      <STATIC_TEXT> 
         <LABEL>Hello</LABEL>
         <REQUEST>Please pay your bill before </REQUEST>
      </STATIC_TEXT>
   </in:TEXT_CONTENT_ENG>

   <xsl:template match="/">
      <output>
         <xsl:apply-templates 
             select="document('')/xsl:stylesheet/in:TEXT_CONTENT_ENG/*"/>
      </output>
   </xsl:template>

   <xsl:template match="STATIC_TEXT">
      <xsl:text>The label is </xsl:text>
      <xsl:value-of select="LABEL"/>
      <xsl:text> and the request is </xsl:text>
      <xsl:value-of select="REQUEST"/>
   </xsl:template>

</xsl:stylesheet>

Answer 3

使用 xalan 我可以这样做：

<xsl:apply-templates select="xalan:nodeset($TEXT_CONTENT_ENG)/STATIC_TEXT"/>

类似的功能也可用于 exslt