在 emacs lisp 中将多个路径组件连接成单个完整路径的正确方法是什么？

Question

假设我有变量 dir 和 file 分别包含表示目录和文件名的字符串。 emacs lisp 中将它们加入到文件的完整路径中的正确方法是什么？

例如，如果 dir 是 "/usr/bin" 且 file 是 "ls"，那么我想要“/usr/bin/ls”。但如果 dir 是 "/usr/bin/"，我仍然想要同样的东西，没有重复的斜杠。

Answer 1

阅读目录名称，你会找到答案：

给定一个目录名称，您可以组合
它与相对文件名使用
连接：

（连接目录名relfile）

请务必验证文件名是
在这样做之前相对。如果你使用
绝对文件名，结果
可能在语法上无效或
引用了错误的文件。

如果你想使用目录文件
在进行这样的组合时，你的名字
必须先将其转换为目录
使用文件名作为目录命名：

（concat（文件名作为目录 dirfile）relfile） 

不要尝试
手动连接斜杠，如

<前><代码> ;;;错误的！
（连接目录文件“/”relfile）

因为它不可移植。总是
使用文件名作为目录。

其他有用的命令有：file-name-directory、file-name-nondirectory 以及 文件名组件 部分。

Answer 2

您可以使用 expand-file-name 来实现此目的：

(expand-file-name "ls" "/usr/bin")
"/usr/bin/ls"
(expand-file-name "ls" "/usr/bin/")
"/usr/bin/ls"

编辑：这只适用于绝对目录名称。我认为特雷的答案是更好的解决方案。

Answer 3

我想将多个嵌套目录加入到一条路径上。最初我使用了多个 expand-file-name 调用，如下所示：

(expand-file-name "b" (expand-file-name "a" "/tmp"))
"/tmp/a/b"

然而，这相当冗长，并且向后读取。

相反，我编写了一个功能类似于 Python 的 os.path.join 的函数：

(defun joindirs (root &rest dirs)
  "Joins a series of directories together, like Python's os.path.join,
  (dotemacs-joindirs \"/tmp\" \"a\" \"b\" \"c\") => /tmp/a/b/c"

  (if (not dirs)
      root
    (apply 'joindirs
           (expand-file-name (car dirs) root)
           (cdr dirs))))

它的工作原理如下：

(joindirs "/tmp" "a" "b")
"/tmp/a/b"
(joindirs "~" ".emacs.d" "src")
"/Users/dbr/.emacs.d/src"
(joindirs "~" ".emacs.d" "~tmp")
"/Users/dbr/.emacs.d/~tmp"

Answer 4

这个问题是在 2010 年提出的，但在撰写本文时，它是“在 elisp 中加入文件路径”等搜索的热门搜索，所以我想我应该更新答案。

自 2010 年以来，Emacs 领域发生了很大变化。这有点重复的答案，因为在下面的答案中简要提到了它，但我会稍微充实它。现在有一个用于文件交互的专用库，f.el：

受到 @magnars 的出色s.el 和 dash.el, f.el 是一个现代 API，用于在 Emacs 中处理文件和目录。

不要试图重新发明轮子。您应该使用此库进行文件路径操作。您想要的功能是 f-join：

(f-join "path")                   ;; => "path"
(f-join "path" "to")              ;; => "path/to"
(f-join "/" "path" "to" "heaven") ;; => "/path/to/heaven"

您可能需要先安装该软件包。它应该在 MELPA 上可用。

Answer 5

对于那些在 2021 年之后提出这个问题的人。elisp 内置函数 file-name-concat 可以完成这项工作。现在简单多了。

可以通过以下按键在 emacs 中找到文档：

Ch f file-name-concat

将 COMPONENTS 附加到 DIRECTORY 并返回结果字符串。

COMPONENTS 中的元素必须是字符串或 nil。
DIRECTORY 或 COMPONENTS 中的非最终元素可能会也可能不会结束
带斜杠——如果它们不以斜杠结尾，则斜杠将是
在连接之前插入。

其他相关函数记录在文件名组中。
可能是在 Emacs 28.1 版本或之前引入的。
此函数不会更改全局状态，包括比赛数据。

(file-name-concat "/usr/bin/" "ls")
;; ==> "/usr/bin/ls"

(file-name-concat "/usr" "bin" "ls")
;; ==> "/usr/bin/ls"

Answer 6

这是我使用的：

(defun catdir (root &rest dirs)
  (apply 'concat (mapcar
          (lambda (name) (file-name-as-directory name))
          (push root dirs))))

与@dbr的区别：

1. 返回一个“emacs目录名称”，即带有尾部斜杠的值
2. 如果root是相对的，则它不会扩展路径（参见注释
3. ） root 作为根，而 joindirs 将使用以 "/" 开头的 first 组件作为根。

注释

许多文件处理函数（全部、大多数、？？？）将规范化冗余斜杠并在相对路径上调用 expand-file-name （或类似的），所以 #2而#3 可能并不重要。

Answer 7

如果您使用方便的文件和目录操作库 f.el ，你只需要 f-join。下面的代码适用于那些由于某种原因拒绝使用这个库的人。

(defun os-path-join (a &rest ps)
  (let ((path a))
    (while ps
      (let ((p (pop ps)))
        (cond ((string-prefix-p "/" p)
               (setq path p))
              ((or (not path) (string-suffix-p "/" p))
               (setq path (concat path p)))
              (t (setq path (concat path "/" p))))))
    path))

这与 Python 的 os.path 完全相同。加入。

ELISP> (os-path-join "~" "a" "b" "")
"~/a/b/"
ELISP> (os-path-join "~" "a" "/b" "c")
"/b/c"

string-suffix-p 不存在 Emacs 24.4之前，所以我在 在 Emacs Lisp 中检查字符串是否以后缀结尾。

Answer 8

只是为了通过 Emacs 手册的链接来完成之前所说的内容：

正如其他人之前所说，OP 问题的答案是使用 expand-file-name。这是一个内置函数，用 C 实现，因此不需要使用任何外部库。

Emacs Lisp 手册 标题为 扩展文件名的函数。

而且根据Emacs在线帮助，这个功能是在Emacs 1.6版本中引入的！所以...它应该可用！