如何在 Perl 中创建二维数组？

Question

我目前正在尝试将 32 x 48 矩阵文件传递到 Perl 中的多维数组。我可以访问所有值，但在访问特定值时遇到问题。

这是数据集的链接： http://paste-it.net/public/x1d5301/

这是我所拥有的现在就获取代码。

#!/usr/bin/perl

open FILE, "testset.txt" or die $!;
my @lines = <FILE>;

my $size = scalar @lines;

my @matrix = (1 .. 32);
my $i = 0;
my $j = 0;
my @micro;

foreach ($matrix)
{
    foreach ($lines)
    {
        push @{$micro[$matrix]}, $lines;
    }
}

Answer 1

您似乎不明白 $matrix 仅在紧随其后的是数组索引器时表示 @matrix：[ $slot ]。否则，$matrix 是与@matrix 完全不同的变量（也与%matrix 不同）。请参阅 perldata。

#!/usr/bin/perl
use English;

不要！使用英语——那样！

这会引入 $MATCH、$PREMATCH 和 $POSTMATCH 并引发可怕的 $&、$` , $' 罚分。您应该等到使用一个英文变量，然后导入它。

open FILE, "testset.txt" or die $!;

两件事：1）使用 词汇 文件句柄，以及 2) 使用三参数 <代码>打开。

my @lines = <FILE>;

只要我选择：不要吞食大文件。 （这里不是这种情况，但这是一个很好的警告。）

my $size = scalar @lines;

my @matrix = (1 .. 32);
my $i = 0;
my $j = 0;
my @micro;

我看到我们正处于 “PROFIT!!” 在此阶段...

foreach ($matrix) {

您没有变量 $matrix；你有一个变量@matrix。

    foreach ($lines) {

$lines 也是如此。

        push @{ $micro[$matrix]}, $lines;
    }
}

改写：

use strict;
use warnings;
use English qw<$OS_ERROR>; # $!
open( my $input, '<', 'testset.txt' ) or die $OS_ERROR;

# I'm going to assume space-delimited, since you don't show
my @matrix;
# while ( defined( $_ = <$input> ))...
while ( <$input> ) {
    chomp; # strip off the record separator
    # Load each slot of @matrix with a reference to an array filled with
    # the line split by spaces.
    push @matrix, [ split ]; # split = split( ' ', $_ )
}

Answer 2

如果您要做大量数学运算，您可以考虑 PDL（Perl 数据语言）。您可以轻松地设置矩阵并在对其进行操作之前：

use 5.010;

use PDL;
use PDL::Matrix;

my @rows;
while( <DATA> ) {
    chomp;
    my @row = split /\s+/;
    push @rows, \@row;
    }

my $a = PDL::Matrix->pdl( \@rows );
say "Start ", $a;

$a->index2d( 1, 2 ) .= 999;
say "(1,2) to 999 ", $a;

$a++;
say "Increment all ", $a;

__DATA__
1 2 3
4 5 6
7 8 9
2 3 4

输出显示了矩阵的演变：

Start 
[
 [1 2 3]
 [4 5 6]
 [7 8 9]
 [2 3 4]
]

(1,2) to 999 
[
 [  1   2   3]
 [  4   5 999]
 [  7   8   9]
 [  2   3   4]
]

Increment all 
[
 [   2    3    4]
 [   5    6 1000]
 [   8    9   10]
 [   3    4    5]
]

有相当大的能力可以对矩阵的每个成员运行任意和复杂的操作，就像我向每个成员添加 1 一样。你完全跳过了循环杂技。

不仅如此，PDL 还做了很多特殊的事情来使数学运算变得非常快并且内存占用很小。您想做的一些事情可能已经实现了。

Answer 3

您可能需要 chomp 这些值：

chomp( my @lines = <FILE> );

Answer 4

澄清与Axeman的答案相切的一点 ：

参见 perldoc -f split：

/\s+/ 上的拆分类似于 split(' ')，只不过任何前导空格都会生成空的第一个字段。不带参数的 split 实际上在内部执行了 split(' ', $_)。

#!/usr/bin/perl

use YAML;

$_ = "\t1 2\n3\f4\r5\n";

print Dump { 'split'       => [ split       ] },
           { "split ' '"   => [ split ' '   ] },
           { 'split /\s+/' => [ split /\s+/ ] }
           ;

输出：

---
split:
  - 1
  - 2
  - 3
  - 4
  - 5
---
split ' ':
  - 1
  - 2
  - 3
  - 4
  - 5
---
split /\s+/:
  - ''
  - 1
  - 2
  - 3
  - 4
  - 5

Answer 5

我发现这个问题已经很老了，但由于作者刚刚编辑了这个问题，也许这仍然很有趣。此外，数据的链接已失效，但由于其他答案使用空格作为分隔符，我也会这样做。

这个答案演示了 Tie::Array::CSV允许随机访问 CSV（或其他可使用 Text::CSV 解析的文件一个>）。

#!/usr/bin/env perl

use strict;
use warnings;

use Tie::Array::CSV;

## put DATA into temporary file
## if not using DATA, put file name in $file
use File::Temp ();
my $file = File::Temp->new();
print $file <DATA>;
##


tie my @data, 'Tie::Array::CSV', $file, { 
  text_csv => {
    sep_char => " ",
  },
};

print $data[1][2];

__DATA__
1 2 3 4 5
6 7 8 9 1
2 3 4 5 6