在 AIR/AS3 中使用特定于移动设备的类测试代码时，如何避免出现VerifyError？

Question

我是一位经验丰富的 AS3 开发人员，第一次进行 AIR 开发是为了创建 iPhone 应用程序。我尝试使用 StageOrientationEvent 和相关类来考虑可变设备方向，并且在尝试在桌面计算机上进行测试时收到了VerifyError，大概是因为与方向相关的类是特定于移动设备的。

iPhone 打包程序的 Adob​​e 文档暗示，只要您在实际使用之前使用 Stage.supportsOrientationChange 等标志来测试功能，就可以测试包含特定于移动设备的代码的应用程序。不幸的是，AIR 似乎在启动时检查不可接受的类，因此该检查是无用的。

如何在桌面上测试此应用程序，而无需在每次切换设备时注释掉特定于移动设备的代码？

相关代码：

package 
{
import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageAlign;
import flash.display.StageOrientation;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.events.StageOrientationEvent;

public class Main extends Sprite 
{
    public function Main():void 
    {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init(e:Event = null):void 
    {
        removeEventListener(Event.ADDED_TO_STAGE, init);

        if (Stage.supportsOrientationChange) 
        {
            stage.addEventListener(StageOrientationEvent.ORIENTATION_CHANGE, onOrientationChange);
        }
    }

    private function onOrientationChange(event:StageOrientationEvent):void
    {
        switch (event.afterOrientation) 
        {
            case StageOrientation.DEFAULT: //ignore.  Landscape.
                break;
            case StageOrientation.ROTATED_RIGHT:
                    stage.setOrientation(StageOrientation.ROTATED_RIGHT);
                break;
            case StageOrientation.ROTATED_LEFT:
                stage.setOrientation(StageOrientation.ROTATED_LEFT);
                break;
            case StageOrientation.UPSIDE_DOWN: //ignore.  Landscape.
                break;
        }
    }
}

}

以及我得到的错误：

[Fault] exception, information=VerifyError: Error #1014: Class flash.events::StageOrientationEvent could not be found.

Answer 1

我发现处理此问题的最佳方法是使用 if 语句包装代码，如下所示：

if(ApplicationDomain.currentDomain.hasDefinition("flash.events.StageOrientationEvent")){
    if(Stage.supportsOrientationChange)
    stage.addEventListener(StageOrientationEvent.ORIENTATION_CHANGE, orientationChange);
}

然后添加通用事件函数并将生成的事件转换为 StageOrientationEvent 类：

private function orientationChange(event : Event):void{
    switch ((event as StageOrientationEvent).afterOrientation) {
        case StageOrientation.DEFAULT:
           break;
    }
}

Answer 2

删除或注释所有不需要的内容，或者不完全支持的内容，以便在桌面内进行测试。您可以做的其他事情是尝试除 StageOrientation 之外的另一种解决方法。有一个很好的例子，使用加速器和舞台宽度和高度来获取设备方向。