XSL：删除 xml 标签但保留其内容

Question

我最近将几个 .xml 文件从 docbook 更改为 dita。转换顺利，但存在一些不需要的工件。我感到困惑的是 .dita 无法识别 docbook 中的 标签，并将其替换为

。您认为这很好，但这会导致 XML 将有序列表中的项目显示为下一行，即：

1
 item One
2
 item Two

而不是：

1 item One
2 item Two

那么我该如何更改此设置：

<section>
<title>Cool Stuff</title>
<orderedlist>
  <listitem>
    <para>ItemOne</para>
  </listitem>

  <listitem>
    <para>ItemTwo</para>
  </listitem>
</orderedlist>

对此：

<section>
<title>Cool Stuff</title>
<orderedlist>
  <listitem>
    ItemOne
  </listitem>

  <listitem>
    ItemTwo
  </listitem>
</orderedlist>

抱歉，我应该把问题说得更清楚。我需要从文档中删除深度不同的所有标签，但始终遵循（本地）树 listitem/para 。我对此有点陌生，但是我可能会因为将其附加到我的 docbook2dita 转换而做错了。可以在那个地方吗？

Answer 1

我会使用这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match ="listitem/para">
        <xsl:apply-templates/>
    </xsl:template>
</xsl:stylesheet>

注意：覆盖身份规则。 listitem/para 被绕过（这保留了混合内容）

Answer 2

您可以使用过滤掉 节点的 XSLT 来处理 dita 文件：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <!-- copy elements and attributes -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- replace para nodes within an orderedlist with their content -->     
  <xsl:template match ="orderedlist/listitem/para">
    <xsl:value-of select="."/>
  </xsl:template>

</xsl:stylesheet>

Answer 3

我遇到了类似的问题，但我使用的是 QtDom，它并不总是像 XSLT 2.x 规范那样 100% 工作。 （我正在考虑在某个时候切换到 Apache 库...）

我想用相应的类更改 div 中代码中的等效“listitem”：

<xsl:for-each select="/orderedlist/lisitem">
  <div class="listitem">
    <xsl:apply-templates select="node()"/>
  </div>
</xsl:for-each>

这将删除 listitem 并将其替换为

然后，模板（在我的例子中，中的内容）可以包含标签，因此我无法使用将所有内容转换为纯文本的其他两个示例。相反，我使用了它：

<xsl:template match ="para">
  <xsl:copy-of select="node()"/>
</xsl:template>

删除了“para”标签，但保持所有子项不变。因此段落可以包含格式，并且在 XSLT 处理过程中会保留格式。