使用delphi枚举单元的全局方法

Question

假设我有一个像这样的单元

unit sample;

interface

function Test1:Integer;
procedure Test2;

implementation

function Test1:Integer;
begin
 result:=0;
end;

procedure Test2;
begin

end;

end.

是否可以在运行时枚举单元sample的所有过程和函数？

Answer 1

不会。RTTI 不是为独立方法生成的。希望这将在以后的版本中得到修复（他们可能需要 TRttiUnit 类型来做到这一点），但目前它不可用。

Answer 2

您可以使用 JCL 和他们伟大的 JclDebug.pas。

试试这个：

uses
  JclDebug;

type
  TProc = record
    name: string;
    addr: Pointer;
  end;

  TProcArray = array of TProc;
  TMapLoader = class
  private
    FModule: Cardinal;
    FProcs: TProcArray;
    FMapFileName: string;
    FUnitName: string;
    procedure HandleOnPublicsByValue(Sender: TObject; const Address: TJclMapAddress; const Name: string);
  public
    constructor Create(const AFileName: string; AModule: Cardinal; const AUnitName: string);
    procedure Scan();
    property Procs: TProcArray read FProcs;
  end;

constructor TMapLoader.Create(const AFileName: string; AModule: Cardinal; const AUnitName: string);
begin
  inherited Create;
  FMapFileName := AFileName;
  FModule := AModule;
  FUnitName := AUnitName;
end;

procedure TMapLoader.HandleOnPublicsByValue(Sender: TObject; const Address: TJclMapAddress; const Name: string);
var
  l: Integer;
begin
  if Pos(FUnitName + '.', Name) = 1 then
  begin
    l := Length(FProcs);
    SetLength(FProcs, l + 1);
    FProcs[l].name := Name;
    FProcs[l].addr := Pointer(Address.Offset + FModule + $1000);
  end;
end;

procedure TMapLoader.Scan();
var
  parser: TJclMapParser;
begin
  parser := TJclMapParser.Create(FMapFileName, FModule);
  try
    parser.OnPublicsByValue := HandleOnPublicsByValue;
    parser.Parse;
  finally
    parser.Free;
  end;
end;

Answer 3

我不这么认为。

这是一个编译时配置，使用它是为了让编译器知道哪个函数名称正在被调用或没有被调用。据我所知，在运行时没有什么比列出这些函数更接近的了。

Delphi 优秀的运行时特性来自 RTTI，您可能想看看它提供了与此相关的功能。但正如我所说，我认为这是不可能的（要知道我已经研究 RTTI 相当长一段时间了......）。

编辑：哦，顺便说一句，编译后，函数会丢失其人类可读的名称（地址）。有一些表可以将这些名称精确定位到地址，最值得注意的是 RTTI 和调试信息。