使用 XML::Simple 时如何删除 Magic Number？

Question

我做了这样的练习，如何计算通过 XML::Simple 折叠到数组中的 XML 元素的数量，这样我就不必对元素的数量进行硬编码？ 我计划使用代码来解析更大的 xml 文件。我不想手动计算元素。

我可以使用一些计数来替换幻数吗，有点像 person.count 或 hobbie.length 等。据我所知，我可以在 C# 中使用这种语句方便。

#!/usr/bin/perl -w
use strict;
use XML::Simple;
use Data::Dumper;

my $tree = XMLin('./t1.xml');

print Dumper($tree);
print "\n";
for (my $i = 0; $i < 2; $i++) # magic number '2'
{
    print "$tree->{person}->[$i]->{first_name} $tree->{person}->[$i]->{last_name}\n";
    print "\n";
    for (my $j = 0; $j < 3; $j++) # magic number '3'
    {
        print $tree->{person}->[$i]->{hobbie}->[$j], "\n";
    }
    print "\n";
}

输出：

could not find ParserDetails.ini in C:/Perl/site/lib/XML/SAX
$VAR1 = {
          'person' => [
                      {
                        'hobbie' => [
                                    'bungy jumping',
                                    'sky diving',
                                    'knitting'
                                  ],
                        'last_name' => 'Bloggs',
                        'first_name' => 'Joe'
                      },
                      {
                        'hobbie' => [
                                    'Swim',
                                    'bike',
                                    'run'
                                  ],
                        'last_name' => 'LIU',
                        'first_name' => 'Jack'
                      }
                    ]
        };

Joe Bloggs

bungy jumping
sky diving
knitting

Jack LIU

Swim
bike
run

我的Xml源文件如下

<Document>
  <person>
    <first_name>Joe</first_name>
    <last_name>Bloggs</last_name>
    <hobbie>bungy jumping</hobbie>
    <hobbie>sky diving</hobbie>
    <hobbie>knitting</hobbie>
  </person>
  <person>
    <first_name>Jack</first_name>
    <last_name>LIU</last_name>
    <hobbie>Swim</hobbie>
    <hobbie>bike</hobbie>
    <hobbie>run</hobbie>
  </person>
</Document>

Answer 1

由于 XML::Simple 将为您生成一个数组，因此很容易计算其长度。

例如，$tree->{person} 是一个数组，或者更确切地说是一个数组引用（即使只有 1 个人，也可以使用 XML::Simple 的 ForceArray 选项来确保它是一个数组）。

• 您可以通过首先将其取消引用到数组本身来获取其长度（使用 @{} 数组取消引用）：@{ $tree->{person} }

• 然后，您在标量上下文中使用结果数组，该数组的计算结果为数组中的元素数量（换句话说，a.lenth/a.count 函数会转换为 Perl 习语 scalar(@a)（如果标量上下文已适用，则 scalar() 函数是可选的）。

  在这种情况下，数字比较运算符“<”将强制使用标量上下文，但如果不是这种情况，您可以使用scalar()函数.

示例：

# Don't forget ForceArray option of XML::Simple to ensure person and hobbie are array refs
for (my $i = 0; $i < scalar( @{ $tree->{person} } ); $i++) { # scalar() is optional here
    print "$tree->{person}->[$i]->{first_name} $tree->{person}->[$i]->{last_name}\n";
    print "\n";
    for (my $j = 0; $j < @{ $tree->{person}->[$i]->{hobbie} }; $j++) {
        print $tree->{person}->[$i]->{hobbie}->[$j], "\n";
    }
    print "\n";
}

请注意，计算 Perl 数组长度的一种稍有不同的方法是 $#a 构造，它返回数组最后一个元素的索引 - 例如，比数组中元素的数量少 1。我不知道使用这两种方法之间有任何性能差异，因此如果您发现两种方法具有相同的可读性，请酌情使用它们（例如，如果您需要获取最后一个元素的索引，请使用 $#a; 如果有 # 个元素，请根据需要使用 @a 或 scalar(@a)）。

一个很好的参考是 Perl Data Structures Cookbook @perldoc

Answer 2

for my $person (@{ $tree->{person} }) {
    print "$person->{first_name} $person->{last_name}\n\n";
    for my $hobby (@{ $person->{hobbie} }) {
      print $hobby, "\n";
    }
    print "\n";
}

正如 DVK 所说，确保你有 ForceArray =>; [qw/Person Hobby/] 在您的 XMLin 选项中，否则如果您只有一个人或任何人只有一种爱好，事情就不会成功。

Answer 3

如果您使用“C”风格的 for 循环，则只需知道数组中的项目数。相反，您可以使用更糟糕的版本： foreach my $val ( @list )

#!/usr/bin/perl

use strict;
use warnings;

use XML::Simple qw(:strict XMLin);
use Data::Dumper;

my $tree = XMLin('./t1.xml', KeyAttr => { }, ForceArray => [ 'person', 'hobbie' ]);

foreach my $person ( @{ $tree->{person} } ) {
    print "$person->{first_name} $person->{last_name}\n";
    foreach my $hobbie ( @{ $person->{hobbie} } ) {
        print "$hobbie\n";
    }
}

为了更安全（并且可以说更具可读性），您可能需要检查 <在尝试循环之前， /code> 具有任何 元素：

foreach my $person ( @{ $tree->{person} } ) {
    print "$person->{first_name} $person->{last_name}\n";
    if(my $hobbies = $person->{hobbie}) {
        foreach my $hobbie ( @$hobbies ) {
            print "$hobbie\n";
        }
    }
}