如何为PowerPC交叉编译Qt X11？

Question

我一直在尝试为 PowerPC 交叉编译 Qt X11 一段时间，但一直遇到各种问题。

根据我提供的 Qt 支持的信息，需要做的就是：

1. 创建一个新的 mkspec
2. 复制 mkspec/ 中的现有目录 我使用了 linux-g++ 并修改了它。
3. 修改 qmake.conf 以使用您的工具链、库和包含

4. 运行以下配置命令：

   ./configure -arch <你的拱门> -xplatform <您的 mkspec> -prefix <您想要安装 Qt 的位置> <其他选项>

5. 配置完成后，运行make，然后运行make install。您会发现 Qt 安装在您在 -prefix 选项中指定的目录中。

这样做遇到了各种各样的问题。

Answer 1

我的解决方案：

1. 将mkspecs/linux-g++复制到mkspecs/linux-g++-
2. 修改mkspecs/linux-g++/qmake.conf代码> 如下例所示。 阅读示例文件中的注释了解具体细节
3. 我不必修改qplatformdefs.h，尽管您可能会针对您的架构
4. 使用问题中的选项运行配置脚本连同 make 和 make install
5. 现在，您可以针对交叉编译的 Qt X11 来编译代码。 moc、uic等已经为你的主机编译好了，所以它们会生成相应的代码。
6. 要使用交叉编译的 Qt 库运行您的软件，只需将 Qt 安装位置的 /libs 复制到目标 lib 文件夹，或者您可以将其放入其他文件夹中，然后设置 LD_LIBRARY_PATH 以包含 Qt lib 文件夹。

示例 qmake.conf：

#
# qmake configuration for linux-g++-ppc_74xx
#

MAKEFILE_GENERATOR = UNIX
TEMPLATE           = app
CONFIG             += qt warn_on release incremental link_prl
QT                 += core gui
QMAKE_INCREMENTAL_STYLE = sublib

include(../common/g++.conf)
include(../common/linux.conf)

#
# Modifications to g++.conf
#
# my_arch-g++ is the full executable path of your g++, make sure your PATH
# contains the directory for your toolchain
#
QMAKE_CC         = my_arch-g++
QMAKE_CXX        = my_arch-g++
QMAKE_LINK       = my_arch-g++
QMAKE_LINK_SHLIB = my_arch-g++

#
# I had to provide includes and libraries for packages my toolchain does not
# provide this is mostly X11 and glib stuff.  You'll either have to
# cross-compile it yourself or get it from your distribution
#
QMAKE_CFLAGS     = -I/path/to/your/includes \
                   -L/path/to/your/libs
QMAKE_CXXFLAGS   = $QMAKE_CFLAGS

#
# Modifications to linux.conf
#
# Same as g++ stuff above
#
QMAKE_AR          = my_arch-ar cqs
QMAKE_OBJCOPY     = my_arch-objcopy
QMAKE_STRIP       = my_arch-strip

#
# I had all kinds of problems linking Qt source with X11 depending on how I
# specified the include paths.  My toolchain provided most X11 functionality
# and I just had to add missing parts in the CXXFLAGS and CFLAGS,
# but specifying exactly where to find X11 includes and libraries specific
# to my toolchain fixed some of the issues I experienced
#
QMAKE_INCDIR_X11  = /path/to/your/toolchain/includes
QMAKE_LIBDIR_X11  = /path/to/your/toolchain/libs

load(qt_config)

更新：

该解决方案适用于“独立”编译。如果您需要为 Angstrom、OpenEmbedded、Android、OpenWRT 等构建 Qt X11，则必须使用它们各自的构建系统才能正确编译。例如，对于 OpenEmbedded 目标（即 Angstrom），您必须编写 BitBake 配方。

出现此问题是由于需要支持遗留系统。使用嵌入式 Qt 不是一个选择。对于新项目，我强烈建议使用嵌入式 Qt。