《归来》 Prolog 中谓词的列表

Question

resolve(K, K, _) :- writeln('finished'). %goal state

resolve(CurrentState, GoalState, Path) :-
    suc(_, CurrentState, NextState, GoalState),
    append(Path, [CurrentState], NextPath),
    resolve(NextState, GoalState, NewPath).

我目前有这个算法，它可以正常工作。我像这样运行它：

resolve(0, 10, Path).

我确信算法正在按其应有的方式运行，它会达到目标状态，尽管 Path 的值

Path = []

不是应该发生的情况。路径应包含我的算法已通过的“状态”序列。 可能是什么问题？

Answer 1

使用 DCG 表示法来描述列表是最简单的：

path(State0, Target) -->
    (    { State0 == Target } -> []
    ;    { suc(_, State0, State1, Target) },
         [State1],
         path(State1, Target)
    ).

您也可以手动完成：

path(State0, Target, Path) :-
    (    State0 == Target -> Path = []
    ;    suc(_, State0, State1, Target),
         Path = [State1|Rest],
         path(State1, Target, Rest)
    ).

这里不需要累加器来获取线性时间。

Answer 2

我相信您构建路径的方式存在问题。
您可能想要重写它，以便将其构建在谓词的头部。
像这样的事情：

resolve(K, K, []) :- writeln('finished'). %goal state
resolve(CurrentState, GoalState, [CurrentState|Path]) :-
    suc(_, CurrentState, NextState, GoalState),
    resolve(NextState, GoalState, Path).

第一个子句结束递归：要从状态 K 转到状态 K，您返回 [] 作为路径，因为您已经处于目标状态。
第二个子句构建路径，它获取下一个状态并递归调用resolve，在递归完成时构建您遍历的路径。

Answer 3

append 谓词中的术语 NextPath 应该是 NewPath 吗？

目前 NextPath 没有任何其他用途，因此 Path 必须绑定到 []，因为 NextPath 能够完全绑定到[CurrentState]。