OO-Perl 类属性别名

Question

我有一个正在开发的模块。我正在设置一些如下属性：

$self->{FOO};
$self->{BAR};
$self->{FOOBAR};

而且，我想使用 AUTOLOAD 来帮助创建访问这些属性的方法。例如，$foo->Bar() 返回$self->{BAR} 的值。没问题。一切都是标准的。

现在，我想创建别名方法。例如，如果有人说 $obj->Fu();，我将返回 $self->{FOO}。我想做的是创建一个 $self->{FU} ，它指向与 $self->{FOO} 相同的内存位置。这样，当我设置 $self->{FOO} 的值时，$self-{FU} 也被设置。这样，我就不必对 AUTOLOAD 的工作方式进行各种更改，也不必在每次设置 $self->{ 时记住设置 $self->{FU} FOO}。

有什么简单的方法可以做到这一点吗？

Answer 1

是的，使用 Moose，而不是尝试在哈希之间进行显式映射
键。编写您自己的访问器或使用 AUTOLOAD 是不必要的，并且可以
出错的可能性要高得多：

package MyClass;

use Moose;
use MooseX::Aliases;

has foo => (
    is => 'rw', isa => 'Str',
    alias => 'fu',
);
has bar => (
    is => 'rw', isa => 'Str',
);
__PACKAGE__->meta->make_immutable;
no Moose;
1;

package main;
use strict;
use warnings;
use MyClass;
my $obj = MyClass->new;
$obj->foo("value");
$obj->fu("a new value");

# prints "foo has the value 'a new value'"
print "foo has the value '", $obj->foo, "'\n";

Answer 2

我会推荐 Moose 超过你正在做的事情，但这是完成你正在做的事情的最简单方法询问可能是这样的：

sub Fu { shift->Foo(@_) }

这样， Foo 是否自动加载并不重要。

Answer 3

非 Moose 解决方案是在符号表中创建一个别名。这不是一件常见的事情，而且我怀疑无论你想做什么，都有更好的方法，无论是 Moose 还是其他方法。如果您可以通过更好的设计或界面来避免它，请不要使用任何这些，这通常是解决此类问题的最佳解决方案。

在此 AUTOLOAD 例程中，我查看 %Aliases 哈希来找出我必须定义的其他方法。当我有别名时，我会在符号表中创建适当的别名。它有点难看，但它避免了在调用堆栈中添加另一个实际方法：

#!perl

use 5.010;

{
package SomeClass;
use Carp;
use vars qw($AUTOLOAD);

sub new {
    return bless { 
        map { $_, undef } qw(FOO BAR FOOBAR)
        }, $_[0];
    };

my %Aliases = (
    FOO => [ qw(fu) ],
    );

sub AUTOLOAD {
    our $method = $AUTOLOAD;
    $method =~ s/.*:://;

    carp "Autoloading $method";

    {
    no strict 'refs';
    *{"$method"} = sub { 
        @_ > 1 
                ? 
            $_[0]->{"\U$method"} = $_[1]
                :
            $_[0]->{"\U$method"}
        };

    foreach my $alias ( @{ $Aliases{"\U$method"} } ) {
        *{"$alias"} = *{"$method"};
        }

    goto &{"$method"};
    }

    }

sub DESTROY { 1 }
}

my $object = SomeClass->new;

$object->foo(5);

say "Foo is now ",   $object->foo;
say "Foo is now ",   $object->foo(9);
say "Fu is now ",    $object->fu;
say "Fu is set to ", $object->fu(17);
say "Foo is now ",   $object->foo;

现在 foo 和 fu 访问相同的东西：

Foo is now 5
Foo is now 9
Fu is now 9
Fu is set to 17
Foo is now 17