将东西放入 HoldPattern 中

Question

我正在生成这样的替换规则列表。

ops = {LessEqual, GreaterEqual};
ineqRules = Table[HoldPattern[Inequality[a_, op1, c_, _, e_]] -> a == c, {op1, ops}]

上面不起作用，因为“op1”被 HoldPattern 从表中隐藏，我该如何修复它？

这是上一个问题的后续问题

Answer 1

编辑怎么样

ops = {LessEqual, GreaterEqual};    
ineqRules = (HoldPattern[Inequality[a_, #, c_, _, e_]] :> a == c) & /@ ops

：要解决贝利撒留的答案中指出的问题，请尝试：

ineqRules=Flatten[{HoldPattern[Inequality[a_,#,c_,___]]:>a==c,HoldPattern[#[a_,c_]&&___]:>a==c}&/@ops]

这显然取决于您有一个简单的结构开始，即没有其他 && 的。

Answer 2

这是 With 的工作：

ops = {LessEqual, GreaterEqual};
ineqRules =
  Table[
    With[{op1=op1},
      HoldPattern[Inequality[a_, op1, c_ ,_ ,e_]] -> a == c
    ],
    {op1, ops}
  ]

Answer 3

我确信应该有更好的方法，但这似乎有效：

ops = {LessEqual, GreaterEqual};
ineqRules[op_] := HoldPattern[Inequality[a_, op, c_, _, e_]] -> a == c;
ineq = Table[ineqRules[op], {op, ops}];
Inequality[1, LessEqual, x, Less, 2] /. ineq

Out: 1 == x

HTH

Edit

请小心这一点：

Inequality[e1, GreaterEqual, e2, Equal, e3] /. ineq
Out> e1 == e2

但

Inequality[1, GreaterEqual, e2, Equal, 2] /. ineq
Out> False

我想如果需要的话，需要一些 Hold[] 野兽才能摆脱困境......让我们知道