复制 XSLT 变量

Question

我正在开发 Umbraco XSL 样式表，但我陷入了困境。

基本上，我有一个参数，我测试并使用它的值（如果存在），否则我使用默认参数 $currentPage。

这是参数

<xsl:param name="source" select="/macro/sourceId" />
<xsl:param name="currentPage" />

这是变量

<xsl:variable name="current">
    <xsl:choose>
        <xsl:when test="$source &gt; 0">
            <xsl:copy-of select="umbraco.library:GetXmlNodeById($source)" />
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy-of select="$currentPage" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:variable>

这是我使用它的地方

<xsl:for-each select="msxml:node-set($source)/ancestor-or-self::* [@isDoc and @level=$level]/* [@isDoc and string(umbracoNaviHide) != '1']">
... code here ...
</xsl:for-each>

简而言之

这可行

<xsl:variable name="source" select="$currentPage" />

这不行

<xsl:variable name="source">
  <xsl:copy-of select="$currentPage" /> <!-- Have tried using <xsl:value-of /> as well -->
</xsl:variable>

那么如何在不使用 select="" 属性的情况下复制变量呢？

更新：我尝试使用另一种方法（见下文），但出现变量超出范围异常。

<xsl:choose>
    <xsl:when test="$source &gt; 0">
        <xsl:variable name="current" select="umbraco.library:GetXmlNodeById($source)" />
    </xsl:when>
    <xsl:otherwise>
        <xsl:variable name="current" select="$currentPage" />
    </xsl:otherwise>
</xsl:choose>

Answer 1

通常，此表达式根据给定条件是 true() 还是 false() 选择两个节点集之一：

$ns1[$cond] | $ns2[not($cond)]

In您的情况这将转换为：

    umbraco.library:GetXmlNodeById($source) 
|
    $currentPage[not(umbraco.library:GetXmlNodeById($source))]

完整的定义是：

<xsl:variable name="vCurrent" select=
"        umbraco.library:GetXmlNodeById($source) 
    |
        $currentPage[not(umbraco.library:GetXmlNodeById($source))]
"/>

这可以用更紧凑的方式编写：

<xsl:variable name="vRealSource" select="umbraco.library:GetXmlNodeById($source)"/>

<xsl:variable name="vCurrent" select=
    "$vRealSource| $currentPage[not($vRealSource)]"/>

Answer 2

每当您在 XSLT 1.0 中声明一个不带 @select 的变量，但使用某些内容模板时，该变量类型将为结果树片段。该变量保存该树片段的根节点。

因此，这样：

<xsl:variable name="source"> 
  <xsl:copy-of select="$currentPage" />
</xsl:variable> 

您将 $source 声明为 RTF 的根，其中包含 $currentPage副本 > 节点集。

您不能将 / 步进运算符与 RTF 一起使用。这就是您使用 node-set 扩展函数的原因。

但是，当你说：

node-set($source)/ancestor-or-self::*

这将被评估为一个空节点集，因为根节点没有祖先并且它不是一个元素。

编辑：如果您有两个节点集，并且您想根据某些条件声明一个包含两个节点集之一的内容的变量，您可以使用：

<xsl:variable name="current" 
              select="umbraco.library:GetXmlNodeById($source)[$source > 0]
                      |$currentPage[0 >= $source]" />