如何在 Perl 中序列化闭包？

Question

我认为最好用一个例子来问这个问题：

use strict;
use warnings;
use 5.010;
use Storable qw(nstore retrieve);

local $Storable::Deparse = 1;
local $Storable::Eval    = 1;

sub sub_generator {
    my ($x) = @_;

    return sub {
        my ($y) = @_;
        return $x + $y;
    };
}

my $sub = sub_generator(1000);
say $sub->(1); # gives 1001
nstore( $sub, "/tmp/sub.store" );
$sub = retrieve("/tmp/sub.store");
say $sub->(1); # gives 1

当我转储 /tmp/sub.store 时，我看到：

$VAR1 = sub {
            package Storable;
            use warnings;
            use strict 'refs';
            my($y) = @_;
            return $x + $y;
        }

但是 $x 从未在此子中定义。我希望由 sub_generator 生成的 sub 在生成时将 $x 替换为其实际值。我应该如何解决这个问题？

请注意，此问题与此一个相关。

Answer 1

不幸的是，我认为 Storable 不适用于闭包。然而，还有其他 CPAN 模块可以序列化闭包。例如。 Data::Dump::Streamer

use 5.012;
use warnings;
use Data::Dump::Streamer;

sub sub_generator {
    my ($x) = @_;

    return sub {
        my ($y) = @_;
        return $x + $y;
    };
}

my $sub = sub_generator(1000);
say $sub->(1); # gives 1001

my $serialised = Dump( $sub )->Out;
my $copy = do {
    my $CODE1 = undef;
    eval $serialised;
    $CODE1;
};

say $copy->(2); # gives 1002
say $sub->(1);  # still gives 1001

这是此处打印的序列化代码是什么样子的，说 Dump $sub;：

my ($x);
$x = 1000;
$CODE1 = sub {
           use warnings;
           use strict 'refs';
           BEGIN {
             $^H{'feature_unicode'} = q(1);
             $^H{'feature_say'} = q(1);
             $^H{'feature_state'} = q(1);
             $^H{'feature_switch'} = q(1);
           }
           my($y) = @_;
           return $x + $y;
         };

更新

请参阅此帖子 Perl5 搬运工邮件列表中的可存储和闭包。它证实了我对 Storable 和闭包的想法。

/I3az/