如何用 Perl 实现一个简单的 IRC 客户端？

Question

我正在开发一个需要将 IRC 消息发送到内部 IRC 频道的工具。这不是一个持续运行的程序，而是一个偶尔被调用的工具，并且需要能够在调用时用几条消息通知通道。

我查看了 Net::IRC，但它自 2004 年以来就已经死了。所以我查看了它列出的替代方案（Bot::BasicBot 和 POE::Component::IRC），但这两个都需要在POE 及其事件循环。对于 Net::Async::IRC 因为它需要在 IO::Async 事件循环中运行。

我不是在编写一个需要与任何东西交互的成熟机器人，我只是想登录到 irc 服务器，加入频道，发布一些快速消息，然后离开。我不想为了做到这一点而必须重新编写整个程序以适应某些框架的事件循环。

那么，对于简单 IRC 客户端的库有什么建议，并且不会让我重写整个应用程序吗？

Answer 1

使用 AnyEvent::IRC::Client，同时使用 AnyEvent“事件循环” ，您不必重写您的应用程序即可使用它，您可以执行以下操作：

use AnyEvent;
use AnyEvent::IRC::Client;

与模块的其余部分一起使用行；和类似的东西

sub do_irc {
    my $log_chan = '#foobar';
    my $timer; 
    my $c = AnyEvent->condvar;
    my $con = new AnyEvent::IRC::Client;

    $con->reg_cb( join => sub {
        my ($con, $nick, $channel, $is_myself) = @_; 
        if ($is_myself && $channel eq $log_chan) {
           $con->send_chan( $channel, PRIVMSG => ($channel, 'my information') );
           $timer = AnyEvent->timer ( 
                after => 1,
                cb => sub {
                    undef $timer;
                    $con->disconnect('done');
                });
        }
    });

    $con->connect($irc_serv, 6667, { nick => $your_nick } );
    $con->send_srv( JOIN => ($log_chan) );
    $c->wait;
    $con->disconnect;

}

来进行连接，它只会在完成后返回（为简洁起见，省略了错误处理）。您的应用程序中没有其他内容需要使用 AnyEvent。

Answer 2

Net::IRC 仍然完全可用，如果您想做的只是像您描述的那样简单的事情，我认为它会做得很好。

也就是说，习惯 POE 根本不是一个坏主意，特别是因为 IRC 机器人的功能往往会随着时间的推移而增长:)

Answer 3

请注意，实际上没有什么可以阻止您使用 PoCo-IRC 或 BasicBot。是的，它们在 POE 下运行，但 POE 无法控制您的整个应用程序。

如果您只是连接，在 IRC 上做一些事情，断开连接，以及做其他事情，您可以确保 IRC 会话在完成后自行销毁 - 当没有剩余会话时， POE::Kernel ->run 会将控制权返回给您的程序。

如果您正在处理寿命较长的连接，但仍想扭转控制，POE 提供了 run_one_timeslice 和 run_while 方法，可让您精细控制何时和何时POE 运行的地方。当然，您必须安排它至少足够频繁地运行，以响应任何服务器 PING 并防止套接字缓冲区被填满。

实际上，Net::IRC 在用自己的事件循环接管您的应用程序时做了完全相同的事情——除了它不是像 POE 或 AnyEvent 这样的命名事物——它只是“Net::IRC 事件循环”。这并不意味着您需要完全重写才能使用 Net::IRC，也不意味着您需要完全重写才能使用 POE :)

Answer 4

使用 MkV 的答案，我能够创建一个有效的命令行脚本：

#!/usr/bin/perl

use strict;
use warnings;
use AnyEvent;
use AnyEvent::IRC::Client;
use Data::Dumper ();
use Getopt::Long;

my %opt = (
    channel => '#ircmsgtest',
    nick    => "ircmsg$",
    port    => 6667,
    server  => 'irc.freenode.net',
    verbose => undef,
);

GetOptions(\%opt,'channel','nick', 'port', 'server', 'verbose|v');
my $message = shift() || "test message @{[ scalar localtime() ]}";
if ($opt{verbose}) {
    warn "message is: '$message'";
    warn Data::Dumper->Dump([\%opt], [qw(*opt)]);
}

my $c = AnyEvent->condvar;
my $con = AnyEvent::IRC::Client->new;

$con->reg_cb(
    join => sub {
        my ($con, $nick, $channel, $is_myself) = @_; 
        if ($is_myself && $channel eq $opt{channel}) {
            $con->send_chan($channel, PRIVMSG => $channel, $message);
            $c->send;
        }
    }
);

$con->connect($opt{server}, $opt{port}, { nick => $opt{nick} } );
$con->send_srv(JOIN => $opt{channel});
$c->wait;
$con->disconnect;

它连接、发送消息，然后断开连接，这非常适合我的需求。