我可以在 Perl 中的硬编码地址处调用子例程吗？

Question

假设我有以下代码：

my $compiled = eval 'sub { print( "Hello World\n" ); }';

我可以通过编写来调用它：

$compiled->();

到目前为止一切顺利。现在想象我创建 10 个函数：

my @fns = ();
for ( my $i = 0; $i < 10; $i++ ) {
  push( @fns, eval "sub { print( 'I am function $i\n' ); }" );
}

我可以按如下方式调用这 10 个函数：

foreach ( @fns ) {
  $_->();
}

现在，我想创建一个动态函数，显式调用我的 10 个函数中的每一个：

my $evalcode = "sub {";
foreach ( @fns ) {
    # if I print $_ it shows something like
    #   "CODE(0x94084f8)", but trying to
    #   call "CODE(0x94084f8)->()" is invalid
    $evalcode .= "$_->();";
}
$evalcode .= "}";


my $dynamic_fn = eval $evalcode;
$dynamic_fn->();

是否可以采用对子例程的字符串化引用并直接调用它？

PS你问为什么？因为我想编写一个动态例程，构造一个 if ( m/.../ ) { } elsif ( m/.../ ) { } ... 检查链，然后调用取决于输入字符串的动态函数。

Answer 1

您可能希望使用常规的词法闭包而不是字符串评估：

my @functions;

for my $i (0 .. 9) {
    push @functions, sub { print "I am function $i\n" };
}

my $call_all_funcs = sub {
    for my $func (@functions) {
        $func->();
    }
};

$call_all_funcs->();

也可以根据其地址检索代码引用，但这会更复杂，更难以理解，并且通常不是一个好主意。

Answer 2

使用闭包而不是 eval 字符串怎么样？

sub combine_subrefs {
  my @subs = @_;
  return sub { foreach my $subref (@subs) { $subref->() } };
}

my $dynamic_fn = combine_subrefs( @fns );
$dynamic_fn->();

我相信你也可以调整它来完成你提到的 elsif 事情。

Answer 3

回复：你问为什么？因为我想编写一个动态例程，构造一个 if ( m/.../ ) { } elsif ( m/.../ ) { } ... 检查链，然后根据输入字符串调用动态函数.

创建一个if &像上面描述的 elsif 链可以完成，而不必求助于 eval< /code>：

use 5.012;
use warnings;

my $build_ifelse_dispatch_table = sub {
    my @functions = @_;

    sub {
        my $text = shift;
        for (@functions) {
            my ($re, $code) = @$_;
            if ($text =~ $re) {
                $code->();
                last;
            }
        }
    };
};

my $dispatch_on = $build_ifelse_dispatch_table->( 
    [ qr/tom/   => sub { say "Tom!"   } ],   # if    (m/tom/)   { ... }
    [ qr/dick/  => sub { say "Dick!"  } ],   # elsif (m/dick/)  { ... }
    [ qr/harry/ => sub { say "Harry!" } ],   # elsif (m/harry/) { ... }
);


$dispatch_on->( 'peeping tom'         );  # Tom!
$dispatch_on->( 'spotty dick pudding' );  # Dick!
$dispatch_on->( 'harry potter'        );  # Harry!
$dispatch_on->( 'Tom, dick and harry' );  # Dick!

参考：调度表上的维基百科条目。

/I3az/

Answer 4

当您打印子例程引用时，您会看到类似 CODE(0xDEADBEEF) 的内容，因为这就是 Perl 对引用进行字符串化的方式。如果您打印任何类型的不重载字符串化的引用，您会看到这样的事情：

 $ perl -le 'print []'
 ARRAY(0x1008032b8)

通常您不能真正将该值用于任何用途，并且您看到的数字不一定对应于真实的内存地址。

对于您正在做的事情，请参阅我在掌握 Perl 中的动态子例程章节。我谈了很多关于编写子例程和使用匿名子例程可以做的不同事情。像 Data::Constraint 这样的模块甚至可能会给你一些想法。我还在 Perl 如何强制其调用者返回？ 的回答中讨论了这一点。

Answer 5

也许有可能（请参阅这个类似的问题和解决方案），但也许还有另一种方法。将字符串化代码引用映射到实际代码引用的（全局？）哈希怎么样？

my @fns = ();
for ( my $i = 0; $i < 10; $i++ ) {
  my $fn = eval "sub { print('I am function $i\n'); } ";
  if (ref $fn eq 'CODE') {
      $CODETABLE{$fn} = $fn;
  }
  push @fns, $fn;
}

...

my $evalcode = "sub {";
foreach ( @fns ) {
    # convert stringified code ref to the actual code ref
    $evalcode .= "\$CODETABLE{\"$_\"}->();";
}
$evalcode .= "}";

(eval $evalcode)->();

---

I am function 0
I am function 1
I am function 2
I am function 3
I am function 4
I am function 5
I am function 6
I am function 7
I am function 8
I am function 9