Vim 自动缩进：对齐跨多行的数组初始化

Question

有时，C 中的数组初始化会跨越多行，尤其是当数组是多维时。在 Emacs 中，自动缩进的结果如下所示：

int a[N][N] = {{0, 0, 6, 7, 0, 4, 0, 2, 0},
               {0, 5, 0, 6, 0, 0, 0, 0, 1},
               {2, 0, 0, 0, 0, 8, 0, 0, 4},
               {4, 0, 9, 5, 0, 7, 0, 0, 3},
               {0, 0, 0, 0, 0, 0, 0, 0, 0},
               {8, 0, 0, 2, 0, 1, 9, 0, 6},
               {6, 0, 0, 1, 0, 0, 0, 0, 7},
               {3, 0, 0, 0, 0, 5, 0, 6, 0},
               {0, 2, 0, 3, 0, 6, 1, 0, 0}};

在 Vim 中，由 :filetype indent on 启用的自动缩进功能仅将行缩进常量 shiftwidth，这会导致以下内容：

int a[N][N] = {{0, 0, 6, 7, 0, 4, 0, 2, 0},
    {0, 5, 0, 6, 0, 0, 0, 0, 1},
    {2, 0, 0, 0, 0, 8, 0, 0, 4},
    {4, 0, 9, 5, 0, 7, 0, 0, 3},
    {0, 0, 0, 0, 0, 0, 0, 0, 0},
    {8, 0, 0, 2, 0, 1, 9, 0, 6},
    {6, 0, 0, 1, 0, 0, 0, 0, 7},
    {3, 0, 0, 0, 0, 5, 0, 6, 0},
    {0, 2, 0, 3, 0, 6, 1, 0, 0}};

有没有办法让 Vim 在这种特殊情况下表现得像 Emacs 一样？

更新：

赫伯特·西茨的回答确实非常有帮助（谢谢！）。我稍微修改了他的代码，如下所示：

setlocal indentexpr=GetMyCIndent()

function! GetMyCIndent()
    let theIndent = cindent(v:lnum)

    let m = matchstr(getline(v:lnum - 1),
    \                '^\s*\w\+\s\+\S\+.*=\s*{\ze[^;]*$')
    if !empty(m)
        let theIndent = len(m)
    endif

    return theIndent
endfunction

将其保存到文件 ~/.vim/after/ftplugin/c.vim 解决了问题，即它使 Vim 以相同的方式对齐数组声明Emacs 确实如此。

我所做的更改：

• 使用 matchstr() 而不是 matchlist() 使代码更易于理解（len(m) 代替len(m[0]))。
• 在行的开头允许有空格，以便声明可以嵌套（例如在函数中）。
• 赋值运算符前允许有两个以上的单词。这负责静态声明。
• 仅检查第一个左括号 ({)，以便表达式也匹配一维数组（或结构）。
• 不要匹配包含分号 (;) 的表达式，因为这表明声明保留在一行中（即下一行不应在左括号下对齐）。我认为这是比在行尾查找右括号或逗号更通用的方法。

如果我错过了一些重要的事情，请告诉我。

Answer 1

有人可能比我更了解，但这是第一次尝试：是的，缩进可以自定义。如果您的文件是可识别的语言“文件类型”，则将使用 /indent 目录中找到的相应 *.vim 文件中的规则/代码（例如 vim/vim72/indent）对其进行缩进。

您需要修改在多行数组上提供缩进的代码，这可能涉及向进行缩进的部分添加一个新的 if 块，其中 if 表达式匹配多行数组的所有且仅第一行。您应该能够通过检查 /indent 目录中的文件来了解事情是如何工作的。

更新：这是 c.vim 缩进文件的一个模块，应该接近你想要的，似乎对我来说工作得很好。这是整个文件：（

" Last Change: 2005 Mar 27

" Only load this indent file when no other was loaded.
if exists("b:did_indent")
   finish
endif
let b:did_indent = 1

" C indenting is built-in, thus this is very simple
setlocal cindent

setlocal indentexpr=GetMyCIndent()
function! GetMyCIndent()
let theIndent = cindent(v:lnum)

let m = matchlist(getline(v:lnum - 1),'^\S\+\s\+\S\+\s*=\s*{\s*{\ze.*}[^}*]')
let m2 = matchlist(getline(v:lnum - 1),'}.*}')
if (!empty(m)) && (empty(m2))
    let theIndent = len(m[0]) - 1
endif

return theIndent

endfunction

let b:undo_indent = "setl cin<"

我认为）这段代码的唯一问题是，它会给数组数组的初始化提供与在一行上完成的相同的缩进。为了避免这种情况，需要修改模式以仅当该行中有一个右括号时才匹配，而不是两个。 （或者，您可以进行单独的测试。）这需要一些技巧，但应该不会太难。 （此外，如果您确实扩展当前模式，则需要在模式中使用 \ze 标记来标记要存储在 m[0] 中的匹配的结尾，该结尾将位于第二个左括号（即最后一个字符）之后在当前模式中。）我修改了上面的代码以进行单独的测试（使用变量 m2），我认为可以解决问题。不确定还需要注意哪些其他小细节。

一种替代方法是，只要行上至少有两个左括号并且最后一个行字符是逗号，您就希望这种缩进行为。这实际上可能是最好的方法，因为它可以让你在一行上有成对、三元组等元素：

let m = matchlist(getline(v:lnum - 1),'^\S\+\s\+\S\+\s*=\s*{\s*{\ze.*,\s*
)
if !empty(m)
    let theIndent = len(m[0]) - 1
endif

Answer 2

我认为您可以输入 :set ai! 然后缩进第二个尺寸线，然后当您按 Enter 并输入第三个尺寸线时，它将正确缩进...如果这不是一个有效的解决方案，抱歉。