Prolog 中列表的自定义反转

Question

我正在尝试编写一个谓词，在 Prolog 中给出以下列表：

[[1,a,b],[2,c,d],[[3,e,f],[4,g,h],[5,i,j]],[6,k,l]]

将生成以下列表：

[[6,k,l],[[5,i,j],[4,g,h],[3,e,f]],[2,c,d],[1,a,b]]

正如您所看到的，我想保留最低级别的元素顺序，以生成顺序为 1, a, b 而不是 b、a、1。

我还想保留列表的深度，即最初嵌套的列表按原样返回，但以相反的顺序返回。

我已经设法使用以下代码实现了所需的顺序，但深度丢失了，即列表不再正确嵌套：

accRev([F,S,T],A,R) :- F \= [_|_], S \= [_|_], T \= [_|_], 
                                 accRev([],[[F,S,T]|A],R).
accRev([H|T],A,R) :- accRev(H,[],R1), accRev(T,[],R2), append(R2,R1,R).
accRev([],A,A).
rev(A,B) :- accRev(A,[],B).

我将不胜感激帮助纠正代码以保留列表的正确嵌套。谢谢！

Answer 1

两个建议。首先，这是一个 (rev_lists/2)，它使用了一堆 SWI-PROLOG 内置函数：

rev_lists(L, RL) :-
    forall(member(M, L), is_list(M)), !,
    maplist(rev_lists, L, L0),
    reverse(L0, RL).
rev_lists(L, L).

这个通过测试列表 L 的所有元素本身是否是列表来工作(M);如果是这样，它将递归地将自身（通过maplist）应用于所有单独的子列表，否则它将返回相同的列表。这样就达到了需要的效果了。

其次，这里又是 rev_lists/2，但编写方式使其不依赖于除 member/2（这是常见的）之外的内置函数：

rev_lists(L, RL) :-
    reversible_list(L), !,
    rev_lists(L, [], RL). 
rev_lists(L, L).

rev_lists([], Acc, Acc).
rev_lists([L|Ls], Acc, R) :-
    (   rev_lists(L, RL), !
    ;   RL = L
    ),
    rev_lists(Ls, [RL|Acc], R).

reversible_list(L) :-
    is_a_list(L),
    \+ (
        member(M, L),
        \+ is_a_list(M)
    ).

is_a_list([]).
is_a_list([_|_]).

它基本上是相同的策略，但使用累加器在每个级别构建反向列表，前提是它们仅由列表组成；否则，返回相同的列表。