转换 c++ printf 格式与 VB .NET 字符串格式之间的转换

Question

我有一些 VB .NET 软件，可以连接到大量旧的（但健全的）COM 对象。 VB 为 COM 对象提供了一个 GUI，其中一部分包括在 COM 对象上设置各种选项 - 其中一些选项与字符串格式相关。

我有一对简单的 VB .NET 函数，它们使用涵盖特定常见字符串的大型选择案例将基本 %f、%d、%g 格式转换为 .NET 等效格式，但它们并不涵盖所有格式。这就是我所拥有的……

        ElseIf f = "%.3f" Then
            return "0.000"
        ElseIf f = "%.2f" Then
            return "0.00"
        ElseIf f = "%.1f" Then
            return "0.0"

在我开始深入研究并通过一些解析使其更加通用之前，有人知道有一个类（例如 VB 或 C# .NET）可以提供不错的现成实现吗？或者也许可以使用一些正则表达式向导？

非常感谢

蒂姆

Answer 1

您是否真的需要这两种格式，或者您的用户采用一种格式，而另一种格式在您的软件的实现细节中使用 - 但如果您具有直接识别用户选项的字符串格式化函数，则可能会消失？

Answer 2

你不需要。 Windows 内置了这种格式。您可以简单地从 User32.dll P/Invoke wsprintf 。

Answer 3

Private Const _format_string = "\%(?<length>\d+)?(\.?(?<precision>\d+)?)(?<type>\w)"

Public Shared Function ToNet(format As String) As String
    Dim regex As New Regex(_format_string, RegexOptions.IgnoreCase _
                           Or RegexOptions.CultureInvariant _
                           Or RegexOptions.IgnorePatternWhitespace _
                           Or RegexOptions.Compiled)

    Dim m As Match = regex.Match(format)
    Dim numberTypeFormat As String = String.Empty
    Dim precision As Integer = 1
    Dim precisionFieldName As String = "precision"

    If m.Success Then
        Select Case m.Groups("type").Value
            Case "d", "i", "n", "u", "o"
                numberTypeFormat = "D"
                precisionFieldName = "length"

            Case "x", "X"
                numberTypeFormat = "X"

            Case "f", "F"
                numberTypeFormat = "N"
                precision = 6

            Case "e", "E"
                numberTypeFormat = "E"
                precision = 6

            Case "s"
                Throw New ArgumentException("String type format string not supported", "format")

        End Select

        If m.Groups(precisionFieldName).Success Then
            precision = Integer.Parse(m.Groups(precisionFieldName).Value)

        End If

        Return String.Format("{0}{1}", numberTypeFormat, precision)


    Else
        Throw New ArgumentException("C++ Format string not recognized", "format")

        Return String.Empty

    End If

End Function