AS3 一般从（对象）数组中删除元素

Question

有没有一种方法可以从数组中普遍删除对象？
（也许不使用 array.filter 或创建新数组）

示例：

var arr:Array= new Array();    
//create dummy objs
for (var i:uint=0; i < 10; i++){
            var someObject:SomeClassObject = new SomeClassObject();
            someObject.Name ="Amit"+ i;
            someObject.Site="http://www.mysite.com/"+i;
           //...many more props
            arr.push(someObject);
 }
//
removeElement("Amit4",arr);
removeElement("Amit8",arr);
//...so on so forth

目前我使用 array.splice() 来删除对象

for (var i:Number=0; i < arr.length; i++)
    {
        if (arr[i].Name == element)
        {
            arr.splice(i, 1);
        }               
    }

我想以这样的方式编写removeElement，以便我可以将它用于不同的用途 对象类型。
目前，removeElement 变得依赖于实现..
假设如果我想从给定文件名的文件数组中删除一个文件..我必须这样做 通过更改条件再次写入“removeElement”。

另外，我可以改变标准吗？ 示例：

arr= removeElement("Site","http://www.mysite.com/6",arr)

将从 arr 中删除“Site”属性等于“http://www.mysite.com/6”的对象 （使用上面的例子）

ie. removeElement(criteria:object,criteria_value(s):object,arr)

谢谢大家。

Answer 1

使用

if(array.indexOf(obj) != -1)
array.splice(array.indexOf(obj),1); 

Answer 2

我认为最灵活的方法是Array::filter。由调用者通过函数回调来确定是否应从列表中过滤掉某个项目。

现在，如果您想就地执行此操作，您可以编写一个像这样的简单函数：

function remove(list:Array,callback:Function):Array {
    for(var i:int = list.length - 1; i >= 0; i--) {
        if(!callback(list[i])) {
            list.splice(i,1);
        }
    }
    return list;
}

这将返回列表，因为如果您想链接调用，它可能会很方便，但它作用于您传递的数组，而不是创建新的数组一。

另请注意，它向后循环。否则，拼接会给你带来虚假的结果。

你可以这样使用它：

var arr:Array = [1,2,9,10,455];
trace(arr);

function removeCallback(item:Number):Boolean {
    return item < 10;
}
remove(arr,removeCallback);
trace(arr);

这样你就不会受到平等（或不平等）的限制。调用者通过分别返回 true 或 false（以匹配 filter）来确定是否应保留或删除该项目。因此，它非常类似于 filter，只不过它就地工作。如果需要，您还可以为回调保留相同的接口（传递项目的索引和对原始数组的引用）以使其更加连贯。

Answer 3

顺便说一句，您可以使用字符串作为数组的索引，然后您可以安全地使用“delete”关键字从数组的“中间”内部删除对象（在这种情况下实际上没有“中间”:) 。
例如：

var arr:Array = new Array();

arr['o1'] = new Object();
arr['o1'].someproperty = true;
arr['o2'] = new Object();
arr['o2'].someproperty = true;
arr['o3'] = new Object();
arr['o3'].someproperty = true;

trace (arr['o2'].someproperty);
//Returns 'true'
trace (arr['o2']);
//Returns '[object Object]'

delete arr['o2'];
trace (arr['o2']);
//Returns 'undefined'
trace (arr['o2'].someproperty);
//Returns 'TypeError: Error #1010: A term is undefined and has no properties.'

缺点是你无法知道数组的长度（arr.length将返回0），但你当然可以自己跟踪它......

Answer 4

这是一个通用函数，它将执行您想要的操作：

public static function removeItem(array: Array, propertyName: String, value: String): Array
{
    var newArray: Array = [];
    for (var index: int = 0; index < array.length; index++) {
        var item: Object = array[index];
        if (item && item.hasOwnProperty(propertyName)) {
            if (item[propertyName] != value)
                newArray.push(item);
        }
    }
    return newArray;
}