如何创建批处理文件来重命名文件夹中的大量文件？

Question

我想重命名 WinXP 系统上文件夹中的大量文件，最好使用批处理文件。

这些文件目前的命名方式如下：

假期2010 001.jpg
假期2010 002.jpg
假期2010 003.jpg

我想将它们更改为：

十二月001.jpg
十二月002.jpg
十二月003.jpg

我该如何执行此操作？

Answer 1

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
SET old=Vacation2010
SET new=December
for /f "tokens=*" %%f in ('dir /b *.jpg') do (
  SET newname=%%f
  SET newname=!newname:%old%=%new%!
  move "%%f" "!newname!"
)

其作用是循环遍历批处理文件所在文件夹中的所有 .jpg 文件，并将文件名中的 Vacation2010 替换为 December。

Answer 2

dir /b *.jpg >file.bat

这将为您提供诸如以下的行：

假期2010 001.jpg
假期2010 002.jpg
假期2010 003.jpg

在您最喜欢的 Windows 中编辑 file.bat 文本编辑器，相当于：

s/Vacation2010(.+)/rename "&" "December \1"/

这是一个 正则表达式；许多编辑器都支持它们，但 Windows 中没有一个默认支持它们（据我所知）。您还可以获得命令行工具，例如 sed 或 perl，在转义命令行后，它们可以采用我上面的确切语法。

结果行将如下所示：

重命名“Vacation2010 001.jpg”“December 001.jpg”
重命名“Vacation2010 002.jpg”“December 002.jpg”
重命名“Vacation2010 003.jpg”“December 003.jpg”

您可能会将这些行识别为重命名命令，原始列表中的每个文件一个。 ;) 在 cmd.exe 中运行该批处理文件。

Answer 3

您可以轻松完成此操作，无需手动编辑或使用精美的文本编辑器。这是一个 vb 脚本。

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder="c:\test"
Set objFolder = objFS.GetFolder(strFolder)
For Each strFile In objFolder.Files
    If objFS.GetExtensionName(strFile) = "jpg" Then    
        strFileName = strFile.Name
        If InStr(strFileName,"Vacation2010") > 0 Then           
            strNewFileName = Replace(strFileName,"Vacation2010","December")
            strFile.Name = strNewFileName
        End If 
    End If  
Next 

另存为 myscript.vbs 并

C:\test> cscript //nologo myscript.vbs 

Answer 4

@ECHO off & SETLOCAL EnableDelayedExpansion

SET "_dir=" REM Must finish with '\'
SET "_ext=jpg"
SET "_toEdit=Vacation2010"
SET "_with=December"
FOR %%f IN ("%_dir%*.%_ext%") DO (
    CALL :modifyString "%_toEdit%" "%_with%" "%%~Nf" fileName 
    RENAME "%%f" "!fileName!%%~Xf"
)
GOTO end

:modifyString what with in toReturn
    SET "__in=%~3"
    SET "__in=!__in:%~1=%~2!"
    IF NOT "%~4" == "" (
        SET %~4=%__in%
    ) ELSE (
        ECHO %__in%
    )
    EXIT /B

:end

此脚本允许您更改包含具有相同名称的 Vacation2010 的所有文件的名称，但使用 December 而不是 Vacation2010。

如果复制并粘贴代码，则必须将 .bat 保存在照片的同一文件夹中。
如果您想将脚本保存在另一个目录中 [例如，您有一个最喜欢的实用程序文件夹]，您必须使用照片的路径更改 _dir 的值。

如果您必须对其他照片 [或其他文件更改 _ext] 执行相同的工作，则必须使用要更改的字符串更改 _toEdit 的值 [或删除] 和 _with 的值以及您想要代替 _toEdit 的字符串 [SET "_with=" 如果您只是想删除在 _toEdit 中指定的字符串]。

Answer 5

您不需要批处理文件，只需从 powershell 执行此操作：

powershell -C "gci | % {rni $_.Name ($_.Name -replace 'Vacation2010', 'December')}"