如何调整动态加载图像到闪存（as3）的大小

Question

我正在努力寻找正确的 as3 代码来调整图像的大小，一旦图像被动态调用到舞台并放置在 MC 中。 我正在加载使用：

var myLoader :Loader = new Loader(); 
mc.addChild(myLoader);
var url :URLRequest = new URLRequest("myimage.jpg"); 
myLoader .load(url );

舞台最终将打开为全屏（工作正常），因此我需要将图像保持其原始尺寸，该尺寸比舞台大得多。

我需要做的是在加载时将其缩小到与舞台相同的高度，同时保持宽度成比例（哦并将其居中）。 我已经尝试了各种代码，但找不到任何可以工作的东西，因为我所做的就是调整包含图像的 MC 的大小，而不是图像本身。 任何有关正确代码的指导将不胜感激。

我猜它就像这样简单，

 "myimage".x=600;

但如果是这样，编写图像名称的正确方法是什么，正如我所写的，它似乎是错误的。 非常感谢

艾德

Answer 1

我也遇到过这样的问题，你可以试试这个......它对我有用

var my_loader:Loader = new Loader();
        my_loader.load(new URLRequest("underwater.jpg"));
        var holder:MovieClip=new MovieClip();
        my_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, function(){
my_loader.content.width = stage.stageWidth;
my_loader.content.height = stage.stageHeight;

Answer 2

我尝试回答你的问题

 import flash.display.MovieClip;
 import flash.display.Sprite;
 import flash.display.DisplayObject;
 import flash.display.Loader;
 import flash.display.LoaderInfo;
 import flash.events.Event;

   var myLoader:Loader = new Loader(); 
   var image:Bitmap;
   var url :URLRequest = new URLRequest("im1.jpg");
   myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageLoaded);
   myLoader.load(url);

   function onImageLoaded(e:Event):void {
      image = new Bitmap(e.target.content.bitmapData);
      var mw:Number = stage.stageWidth;
      var mh:Number = stage.stageHeight;   
      /* if you set width and height image same with the stage use this */
      image.width = mw;
      image.height = mh;
      mc.addChild(image);
   }

Answer 3

您必须等待图像加载，然后您可以调整加载程序的大小，例如：

package {
 import flash.display.MovieClip;
 import flash.display.Sprite;

 import flash.display.DisplayObject;
 import flash.display.Loader;
 import flash.display.LoaderInfo;
 import flash.events.Event;

 public class Test extends Sprite {

  public function Test(){
    super();

    if (stage) {
      init();
    } else {
     addEventListener(Event.ADDED_TO_STAGE, init, false, 0, true);
    }
  }

  public var mc:MovieClip;

  private function init(e:Event=null):void{
   if (e!=null) {
     e.target.removeEventListener(e.type, arguments.callee);
   }

   mc = new MovieClip();
   addChild(mc);

   var myLoader:Loader = new Loader(); 
   mc.addChild(myLoader);

   // listen when the image is fully loaded
   myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageLoaded);


   var url :URLRequest = new URLRequest("myimage.jpg"); 
   myLoader.load(url);
  }

  private function onImageLoaded(e:Event):void {
   var li:LoaderInfo = e.target as LoaderInfo;
   li.removeEventListener(e.type, arguments.callee);

   // resize the loader while preserving ratio
   var ldr:Loader=li.loader;
   var mw:Number = stage.stageWidth / ldr.width;
   var mh:Number = stage.stageHeight / ldr.height;

   var ratio:Number = (mw < mh) ? mw : mh;

   ldr.width *= ratio;  // you can also use ldr.scaleX=ratio;
   ldr.height *= ratio; // you can also use ldr.scaleY=ratio;

   // center mc on stage
   mc.x=0.5*(stage.stageWidth-mc.width);
   mc.y=0.5*(stage.stageHeight-mc.height);
  }
 }
}

Answer 4

试试这个代码：

img1_mc.scaleX = (stage.stageWidth/img1_mc.width)
img1_mc.scaleY = (stage.stageHeight/img1_mc.height)

Answer 5

您还可以尝试
的 Loader 类
http://www.greensock.com/loadermax/

他们在简化和简化方面做得很好。简化加载过程，除此之外还有一些不错的福利。

检查ImageLoader类
http://www.greensock.com/as/docs /tween/com/greensock/loading/ImageLoader.html

特别是如何在加载之前设置一堆可选的 vars 属性。

这是文档中给出的示例的一小段摘录......

//create an ImageLoader:
 var loader:ImageLoader = new ImageLoader("img/photo1.jpg", 
 //here's the sweet part :)
 {name:"photo1", 
 container:this, 
 x:180, 
 y:100, 
 width:200, //here you could set the stageWidth for instance
 height:150, //and the stageHeight here
 scaleMode:"proportionalInside", //this one will definitely help you , check the docs!
 centerRegistration:true, 
 onComplete:onImageLoad});

Answer 6

我在上面的代码中遇到了很多错误，显然是说不能使用嵌套的公共类或其他东西，所以我删除了包和公共函数，并且我让它与这段代码一起工作，

     import flash.display.MovieClip;
 import flash.display.Sprite;
 import flash.display.DisplayObject;
 import flash.display.Loader;
 import flash.display.LoaderInfo;
 import flash.events.Event;
   var myLoader:Loader = new Loader(); 
   mc.addChild(myLoader);
   myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageLoaded);
   var url :URLRequest = new URLRequest("im1.jpg"); 
   myLoader.load(url);
function onImageLoaded(e:Event):void {
   var bit:Bitmap = e.target.content;
    if(bit != null)
    bit.smoothing = true;
   var li:LoaderInfo = e.target as LoaderInfo;
   li.removeEventListener(e.type, arguments.callee);
   var ldr:Loader=li.loader;
   var mw:Number = stage.stageWidth / ldr.width;
   var mh:Number = stage.stageHeight / ldr.height;
   var ratio:Number = (mw < mh) ? mw : mh;
   ldr.width *= ratio;  // you can also use ldr.scaleX=ratio;
   ldr.height *= ratio; // you can also use ldr.scaleY=ratio;
   mc.x=0.5*(stage.stageWidth-mc.width);
   mc.y=0.5*(stage.stageHeight-mc.height);
  }

甚至在其中添加了一些平滑。
我需要学习，因为我不确定公共职能和私人职能之间有什么区别？

另一个问题是，如果图像与加载图像的 swf 位于同一文件夹中，我可以成功动态加载图像，但如果我尝试将图像保存在单独的文件中并使用

var url:URLRequest 之类的内容调用它们...等（“剧照/image1.jpg”）；他们只是不会加载。看出什么不对了吗？？

帮助

再次非常感谢埃德的

Answer 7

您需要添加一个侦听器来侦听正在加载的内容的 INIT 事件。

而且您不需要调整 image.jpg 文件本身的大小（并且您尝试解决该问题的方式不起作用）。您可以改为调整加载程序的大小。

如果您查看 LoaderInfo 的 AS3 文档，您会在末尾找到一个示例，该示例展示了如何添加侦听器。 （请注意，侦听器被添加到 contentLoaderInfo 对象，而不是 Loader 本身）。

然后，您可以使用事件处理程序来调整大小。 AS3 文档在 initHandler 中显示了一个示例，该示例仅跟踪一些内容。如果你做了 loader.x = 600 那么你就会得到你需要的东西。

Answer 8

我只是在查找如何调整图像大小，发现了这个方便的库 http://jacwright.com/blog/221/high-quality-high-performance-thumbnails-in-flash/

当 Flash 缩小图像尺寸时，将其尺寸调整一半时，其质量最佳然后继续调整大小，直到达到所需的大小

该库为您完成了所有这些

该网站有一些示例，并且指向他的谷歌代码页的链接

可能不完全是您想要的，但它确实工作得很好

Answer 9

我为此苦苦挣扎了一段时间，但如果你使用的是 AS3，只需将 uiloader 对象拖到舞台上并将其源设置为 true，最重要的是，将 scaleContent 属性设置为 true...

这对我来说效果很好，并且需要更少代码：

uiloader.autoLoad = true;
uiloader.scaleContent = true;
uiloader.source = "photos/yourphoto.jpg";