Grails：如何将 Grails 列表导出到 Microsoft Excel？

Question

我有一个包含信息的列表，我想将其导出到 Excel。 我该怎么做？

“导出插件”好用吗？我想我不久前看到过一个将文件导出到 Excel 的功能，但现在找不到了。

Answer 1

如果您想要实际 Excel 文档（而不仅仅是 CSV 文件），我使用了 JExcel 库 取得了一些成功。这是一个快速编写的示例，可能需要一点 Groovy 化。

编辑：更新了我的示例以在控制器中执行此操作。从架构上来说，将其分开一点会更有意义，但这只是为了举例。

import jxl.*
import jxl.write.*

class SomeController {

    def report = {
        def file = createReport(MyDomain.list())

        response.setHeader('Content-disposition', 'attachment;filename=Report.xls')
        response.setHeader('Content-length', "${file.size()}")

        OutputStream out = new BufferedOutputStream(response.outputStream)

        try {
            out.write(file.bytes)

        } finally {
            out.close()
            return false
        }
    }

    private File createReport(def list) {
        WorkbookSettings workbookSettings = new WorkbookSettings()
        workbookSettings.locale = Locale.default

        def file = File.createTempFile('myExcelDocument', '.xls')
        file.deleteOnExit()

        WritableWorkbook workbook = Workbook.createWorkbook(file, workbookSettings)

        WritableFont font = new WritableFont(WritableFont.ARIAL, 12)
        WritableCellFormat format = new WritableCellFormat(font)

        def row = 0
        WritableSheet sheet = workbook.createSheet('MySheet', 0)

        list.each {
            // if list contains objects with 'foo' and 'bar' properties, this will
            // output one row per list item, with column A containing foo and column
            // B containing bar
            sheet.addCell(new Label(0, row, it.foo, format))
            sheet.addCell(new Label(1, row++, it.bar, format))
        }
    }
}

使用此库可以让您执行格式化、使用多个工作表等操作。

Answer 2

Grails 导出插件 的功能非常出色：将域对象（或查询结果）列表导出到单个工作表（或页面），采用多种格式 - 包括 Excel。命名列、指示宽度、动态转换数据的能力非常棒——我已经在几个项目中使用过它。

if( params.format && params.format != "html"){
    response.contentType = grailsApplication.config.grails.mime.types[params.format]
    response.setHeader("Content-disposition", "attachment; filename=Docs_${new Date().format('yyyy-MM-dd')}.${params.extension}")

    List fields = ["documentNo", "modifiedBy", "modifiedDate"]
    Map labels = ["documentNo": 'Document No', "modifiedBy":'Modified by', "modifiedDate":'Last modified']

    def fullDocId = { domain, value ->
        return domain.fullDocId()
    }
    def formatDate = { domain, value ->
        return value.format('yyyy-MM-dd HH-mm')
    }

    Map formatters = [documentNo:fullDocId, modifiedDate:formatDate]
    Map parameters = [title: "${query}", "column.widths": [20, 15, 15]]

    exportService.export(params.format, response.outputStream, Document.list(), fields, labels, formatters, parameters)
}

然而，当我想要除简单列表之外的其他内容时，我也按照 Rob 的建议使用了 JExcel。适合工作的工具等等。 :-)

Answer 3

我已经使用 Grails 的 JXL 插件有一段时间了，它运行得很好。

它甚至可以选择将 Excel 文件写入响应，以便用户可以使用我的 REST 服务直接下载文件。

链接是： http://grails.org/plugin/jxl

下面是一个示例，说明它是多么简单是创建工作簿：

new ExcelBuilder().workbook('/path/to/test.xls') {
    sheet('SheetName') {
        cell(0,0,'DEF')
    }
}

您可以在此处找到更多信息。