使用反引号时转义空格

Question

我进行了搜索，从我的角度来看，使用反引号是解决这个问题的唯一方法。我试图从 Perl 中为目录中的每个文件调用 mdls 命令来查找它的上次访问时间。我遇到的问题是，在我从 find 获得的文件名中，有未转义的空格，bash 显然不喜欢这些空格。在将文件名传递给 mdls 之前，有没有一种简单的方法可以转义文件名中的所有空格。如果这是一个显而易见的问题，请原谅我。我对 Perl 还很陌生。

my $top_dir = '/Volumes/hydrogen/FLAC';

sub wanted { # Learn about sub routines 
    if ($File::Find::name) { 
         my $curr_file_path = $File::Find::name. "\n";
        `mdls $curr_file_path`;
         print $_;
    }
}

find(\&wanted, $top_dir);

Answer 1

如果您只是想要操作系统上次访问时间方面的“上次访问时间”，那么 mdls 是错误的工具。使用perl 的stat。如果您想要根据 Mac 注册应用程序（即 Quicktime 或 iTunes 的歌曲）计算上次访问时间，那么 mdls 可能是正确的工具。 （您还可以使用 osascript 直接查询 Mac 应用程序...）

反引号用于捕获文本返回。由于您使用的是 mdls，我认为捕获和解析文本仍将进行。

所以有以下几种方法：

1. 使用system的列表形式，引用为没有必要（如果你
   不关心返回文本）；

2. 使用String::ShellQuote转义文件发送到 sh 之前的名称；

3. 在发送到 shell 之前构建字符串并用单引号引起来。这比听起来更难，因为带单引号的文件名会打败您的引号！例如，sam's Song.mp4 是一个合法的文件名，但如果用单引号引起来，您会得到 'sam's Song.mp4' 这不是您的意思。 .

4. 使用 open 打开一个通向子进程输出的管道，如下所示：open my $fh, '-|', "mdls", "$curr_file" or die "$!";

String::ShellQuote 示例：

use strict; use warnings;
use String::ShellQuote;
use File::Find;

my $top_dir = '/Users/andrew/music/iTunes/iTunes Music/Music';

sub wanted { 
    if ($File::Find::name) { 
         my $curr_file = "$File::Find::name";
         my $rtr;
         return if -d;
         my $exec="mdls ".shell_quote($curr_file);
         $rtr=`$exec`;  
         print "$rtr\n\n";
    }
}

find(\&wanted, $top_dir);

管道示例：

use strict; use warnings;
use String::ShellQuote;
use File::Find;

my $top_dir = '/Users/andrew/music/iTunes/iTunes Music/Music';

sub wanted { 
    if ($File::Find::name) { 
         my $curr_file = "$File::Find::name";
         my $rtr;
         return if -d;
         open my $fh, '-|', "mdls", "$curr_file" or die "$!";
         { local $/; $rtr=<$fh>; }  
         close $fh or die "$!";
         print "$rtr\n\n";
    }
}

find(\&wanted, $top_dir);

Answer 2

如果您确定文件名不包含换行符（CR 或 LF），那么几乎所有 Unix shell 都接受反斜杠引用，并且 Perl 具有 quotemeta 函数来应用它。

my $curr_file_path = quotemeta($File::Find::name);
my $time = `mdls $curr_file_path`;

不幸的是，这不适用于带有换行符的文件名，因为 shell 通过删除两个字符而不是仅删除反斜杠来处理反斜杠后跟换行符。因此，为了真正安全起见，请使用 String::ShellQuote：

use String::ShellQuote;
...
my $curr_file_path = shell_quote($File::Find::name);
my $time = `mdls $curr_file_path`;

这应该适用于文件名包含除 NUL 字符之外的任何内容，您确实不应该在文件名中使用该字符。

这两种解决方案仅适用于 Unix 风格的 shell。如果您使用的是 Windows，正确的 shell 引用要困难得多。

Answer 3

如果您只想查找上次访问时间，是否有一些奇怪的 Mac 原因导致您不使用 stat？什么时候会比kMDItemLastUsedDate更糟糕？

 my $last_access = ( stat($file) )[8];

看来 kMDItemLastUsedDate 并不总是更新为上次访问时间。如果您通过终端处理文件（例如 cat、more），kMDItemLastUsedDate 不会更改，但从 <代码>统计是正确的。 touch 似乎在这两种情况下都做了正确的事情。

看起来您需要 stat 才能获得真正的答案，但如果您正在寻找通过应用程序的访问权限，则需要 mdls 。

Answer 4

您可以通过将命令表达为列表并结合 IPC::System::Simple:

use IPC::System::Simple qw(capture);

my $output = capture('mdls', $curr_file_path);

Answer 5

在反引号内引用变量名称：

`mdls "$curr_file_path"`;
`mdls '$curr_file_path'`;