当参数类型为开放Char数组时，是否允许使用动态Char数组？

Question

我正在查看Delphi：Char和TCharArray“不兼容类型”的数组并开始试验。我的发现相当有趣。

procedure Clear(AArray: array of Integer);
var
  I: Integer;
begin
  for I := Low(AArray) to High(AArray) do
    AArray[I] := 0;
end;

var
  MyArray: array of Integer;
begin
  Clear(MyArray);
end.

这个简单的小示例展示了如何使用开放数组参数将动态数组传递给过程。它完全按照预期编译和运行。

procedure Clear(AArray: array of Char);
var
  I: Integer;
begin
  for I := Low(AArray) to High(AArray) do
    AArray[I] := #0;
end;

var
  MyArray: array of Char;
begin
  Clear(MyArray);
end.

这是几乎相同的代码，唯一的区别是它使用 Char 数组而不是 Integer。它无法编译。相反，编译器会吐出：

 E2010 Incompatible types: 'Array' and 'Dynamic array'

为什么会这样？

经过一段时间的搜索，我发现了这份 QC 报告。我正在运行 Delphi 2009 并且它仍然在发生。

Answer 1

由于文档特别提到 Char 类型的开放数组参数与动态数组兼容，因此这应该是一个错误。来自“打开数组参数”：

函数 Find（A：Char 数组）：
整数；
[...]
注意： [...]
前面的示例创建了一个函数
接受任何 Char 元素数组，
包括（但不限于）动态
数组。 [...]

Answer 2

您可以使用这种数组，定义您自己的类型：

type
  TCharDynArray = array of char;

procedure Clear(AArray: TCharDynArray);
var
  I: Integer;
begin
  for I := Low(AArray) to High(AArray) do
    AArray[I] := #0;
end;

procedure test;
var
  MyArray: TCharDynArray;
begin
  Clear(MyArray);
end;

此代码可以正常编译。当然它没有做任何有用的事情（AArray 参数没有设置为“var”，因此在为每个项目分配 #0 之前将其复制到堆栈上）。但至少，它可以编译。

在实践中，我发现动态数组（如 TIntegerDynArray）更容易定义或使用高级类型，因为至少它允许您使用 var 将数组作为引用传递，从而避免在堆栈上进行复制，并使您的代码更快。

关于映射到 PChar，这对于所有动态数组都是常见的：您可以将 TIntegerDynArray 映射到指针，然后将其用作 PInteger 或 PIntegerArray：

procedure AddInteger(var Values: TIntegerDynArray; Value: integer);
var n: integer;
begin
  n := Length(Values);
  SetLength(Values,n+1);
  Values[n] := Value;
end;

procedure Loop(V: PInteger);
begin
  if V<>nil then
    while V^<>0 do begin
      write(V^,' ');
      inc(V); // go to next integer in array
    end;
end;

var IntArray: TIntegerDynArray;
begin
  Loop(pointer(IntArray)); // will display nothing, since pointer(IntArray)=nil for IntArray=[]
  AddInteger(IntArray,2);
  AddInteger(IntArray,3);
  AddInteger(IntArray,0);
  Loop(pointer(IntArray)); // will display '2 3 '  
end.

问题是“char 数组”代码与“整数数组”不一致" 当然是在编译器内在函数中，而且 PChar 可以类型转换为字符串。

Answer 3

我认为原因是 char 数组 与 PChar 兼容，因为此代码确实可以编译：

procedure Clear(AArray: array of Char);
var
  I: Integer;
begin
  for I := Low(AArray) to High(AArray) do
    AArray[I] := #0;
end;

var
  MyArray: array of Char;
  P: PChar;
begin
  Clear(P^);
end.

这可能是出于历史原因。

希望巴里·凯利或丹尼·索普将介入并提供更多反馈。

——杰罗恩