如何在 TcustomContol 中使用 Picture.LoadFromFile()

Question

我创建了一个从 TcustomControl 派生的 TSkinPanel，

它有一个 FGraphic：TPicture。

FGraphic 绘制在 TSkinPanel 的画布上，如果从 TObject Inspector 加载图像，则可以正常工作。

但我不会在运行时加载图像“Form1.SkinPanel1.Picture.LoadFromFile('skin.bmp');

Answer 1

您必须使用 TPicture.OnChange 事件，例如：

type
  TSkinPanel = class(TCustomControl)
  private
    FPicture: TPicture;
    procedure PictureChanged(Sender: TObject);
    procedure SetPicture(Value: TPicture);
  protected
    procedure Paint; override;
  public
    constructor Create(Owner: TComponent); override;
    destructor Destroy; override;
  published
    property Picture: TPicture read FPicture write SetPicture;
  end;

  constructor TSkinPanel.Create(Owner: TComponent);
  begin
    inherited;
    FPicture := TPicture.Create;
    FPicture.OnChange := PictureChanged;
  end;

  destructor TSkinPanel.Destroy;
  begin
    FPicture.Free;
    inherited;
  end;

  procedure TSkinPanel.PictureChanged(Sender: TObject);
  begin
    Invalidate;
  end;

  procedure TSkinPanel.SetPicture(Value: TPicture);
  begin
    FPicture.Assign(Value);
  end;

  procedure TSkinPanel.Paint;
  begin
    if (FPicture.Graphic <> nil) and (not FPicture.Graphic.Empty) then
    begin
      // use FPicture as needed...
    end;
  end;

Answer 2

如果调用 Picture.LoadFromFile 时没有出现错误，那么它很可能有效，但您的控件根本没有对更改做出反应。首先要做的是处理 Picture.OnChange 事件处理程序并执行某些操作：如果您自己进行绘画，则只需调用 Invalidate()（如果您使用的是 Picture）要设置一些其他控件来依次进行绘制，请在 OnChange 中执行适当的 Assign()。