Delphi 中 TSomething 的默认参数值

Question

我想知道这在 Delphi 中是否可行（或者是否有一种干净的方法）：

type
 TSomething = record
  X, Y : Integer;
 end;

GetSomething( x, y ) ->返回包含这些值的记录。

...然后你有这个函数以 TSomething 作为参数，并且你想将其默认为

function Foo( Something : TSomething = GetSomething( 1, 3 );

编译器在这里吐出一个错误，但是我不确定是否有解决方法！

这可以做到吗？

Answer 1

使用重载：

procedure Foo(const ASomething: TSomething); overload;
begin
  // do something with ASomething
end;

procedure Foo; overload;
begin
  Foo(GetSomething(1, 3));
end;

Answer 2

最简单的方法是使用重载过程：

program TestOverloading;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TSomething = record
    X,Y : integer;
  end;

const
  cDefaultSomething : TSomething = (X:100; Y:200);

procedure Foo(aSomething : TSomething); overload;
begin
  writeln('X:',aSomething.X);
  writeln('Y:',aSomething.Y);
end;

procedure Foo; overload;
begin
  Foo(cDefaultSomething);
end;

begin
  Foo;
  readln;
end.

Answer 3

使用类而不是记录，像这样的东西就可以做到：

TSomething = class
public 
  X: integer;
  Y: integer
end;

procedure Foo(Something: TSomething = nil);
begin
  if (Something = nil) then
    Something := GetSomething(1, 3);
  ...
end;

Answer 4

如果您使用指针而不是记录类型，则可以使用 nil 作为默认值：

type
  TSomething = record
    X, Y : Integer;
  end;

  PSomething = ^TSomething;

function Foo(Something: PSomething = nil);

实际上，将指针作为参数传递通常更快，因为它避免了复制内存块。