访问加载的 .swf 文件中的函数？

Question

有没有办法在加载的 SWF 文件中调用函数？

基本上，我有一个 .swf 文件 (A)，它加载另一个 .swf 文件 (B)...我只想将 B 视为添加到我的类 .swf“A”中的任何其他实例

---

...使用 .swf 文件类的名称重铸“Loader”：

已加载 .swf 类：

package src {
import flash.display.MovieClip;

public class LoadedSWF extends MovieClip     {
    public function LoadedSWF() {
    }

    public function helloWorld():void
    {
        trace("hello world from loaded swf!");
    }
}
}

主类：

package src {
import flash.display.Loader;
import flash.net.URLRequest;
import flash.display.MovieClip;
import flash.events.Event;

public class Main extends MovieClip {

    private var loader:Loader;

    public function Main() {
        loadSWF("LoadedSWF.swf")
    }

    private function loadSWF(url:String):void {
        var urlRequest:URLRequest = new URLRequest(url);
        loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded, false, 0, true);
        loader.load(urlRequest);
        addChild(loader);

    }

    private function onLoaded(e:Event):void {
        var target:LoadedSWF = e.currentTarget.loader.content as LoadedSWF;
        trace(target);
        target.helloWorld();

        addChild(target);
    }
}

}

Answer 1

有两种情况，即

1. 子 swf(B) 调用父 swf(A) 的函数或
2. 父 swf(A) 调用加载的 swf(B) 的函数。

首先，在这两种情况下，您必须确保加载的 swf(B) 已被加载使用 Event.COMPLETE 加载并添加到 Loader swf(A)。这样两个swf之间的通信就可以了。加载的 swf 就像任何其他子文件一样。

以下是情况 2 的示例代码

var mLoader:Loader = new Loader();
mLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompleteHandler);
mLoader.load(new URLRequest("B.swf"));

public function onCompleteHandler(evt:Event)
{
    var embedSWF:MovieClip = MovieClip(evt.target.content);
    addChild(embedSWF);
    embedSWF.function_OF_B();
}

embedSWF.function_OF_B() 语句将调用子 swf B 的函数，即 function_OF_B()

Answer 2

在 Adob​​e Flex 中，您可以使用 flash.display.Loader 类加载另一个 SWF，并向其添加事件侦听器。

此示例取自 Adob​​e 文档：

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);

function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

由于 contentLoaderInfo 是 EventDispatcher 的子类，因此您还可以将事件分派到加载的 SWF。
这基本上就像从 SWF 中调用函数一样，只是稍微复杂一些。