groovy / grails / 单元测试 / createCriteria.get

Question

我可以模拟调用：

MyDomainClass.createCriteria().list{
    eq('id',id)
    eq('anotherParameter',anotherParameterId)
}

with:

def myCriteria = [
    list : {Closure  cls -> returnThisObject}
]
MyDomainClass.metaClass.static.createCriteria = { myCriteria }

按照以下建议：

http ://davistechyinfo.blogspot.com/2010/01/mocking-hibernate-criteria-in-grails.html

但是：

MyDomainClass.createCriteria().get{
    eq('id',id)
    eq('anotherParameter',anotherParameterId)
}

这种方法失败了 - 也许是因为“get”是一个关键字，“list”是不是。任何人都可以建议 - 能够在域类中模拟这一点应该是可能的，而不必简​​单地放弃使用 createCriteria().get{} 的方法的单元测试覆盖率。

非常感谢建议，

亚历克斯

Answer 1

我找到了一个不会损害我编写单元测试的能力的解决方案 -

def myCriteria = new Expando();
myCriteria .get = {Closure  cls -> returnThisObject}         
MyDomainClass.metaClass.static.createCriteria = {myCriteria }

它完全符合我的要求，并且可能支持测试提供的参数。感谢其他人的回复。希望这对其他测试域/createCriteria() 方法的人有用。

Answer 2

我不会打扰。相反，在您的域类中创建方法并模拟它们。这使得测试变得更容易，但更重要的是具有将持久性保持在其所属位置的优点，而不是将其分散在整个代码库中：

class MyDomainClass {
   String foo
   int bar

   static MyDomainClass findAllByIdAndAnotherParameter(long id, long anotherParameterId) {
      createCriteria().list {
         eq('id',id)
         eq('anotherParameter',anotherParameterId)
      }
   }

   static MyDomainClass getByIdAndAnotherParameter(long id, long anotherParameterId) {
      createCriteria().get {
         eq('id',id)
         eq('anotherParameter',anotherParameterId)
      }
   }
}

然后在测试中，只需将其模拟为

def testInstances = [...]
MyDomainClass.metaClass.static.findAllByIdAndAnotherParameter = { long id, long id2 ->
   return testInstances
}

和

def testInstance = new MyDomainClass(...)
MyDomainClass.metaClass.static.getByIdAndAnotherParameter = { long id, long id2 ->
   return testInstance
}

Answer 3

现在使用 GrailsUnitTestCase.mockDomain1 方法。

grails-app/domain/sandbox/grails/foo/Something.groovy

package sandbox.grails.foo

class Something {
    String name
}

测试/unit/sandbox/grails/foo/SomethingTests.groovy

package sandbox.grails.foo

import grails.test.mixin.*
import org.junit.*

@TestFor(Something)
class SomethingTests {

    void testSomething() {

        mockDomain(Something, [
            new Something(name: 'Foo'),
            new Something(name: 'Bar'),
            new Something(name: 'Boo'),
            new Something(name: 'Baz')
        ])

        def actuals = Something.createCriteria().list(sort: 'name', order: 'asc') {
            like('name', '%oo')
        }

        assertEquals 2, actuals.size()

    }
}