SQL 将 int 转换为时间

Question

我有一个将时间显示为整数的数据库。但是我想将其输出到具有正确格式的报告中。这是我想更改的格式：

例如。

• 183000 将变为 18:30
• 500 将变为 00:05
• 160000 将变为16:00

等等。

我已经查看并进行了 CAST 和 CONVERT，但没有成功地以正确的格式获取该时间。

Answer 1

假设您的输入始终是 int，您可以使用以下内容解析它：

DECLARE @stringTime varchar(6)

SET @stringTime =  RIGHT('000000' + CAST(intTime AS VARCHAR), 6)

SELECT CAST(LEFT(@stringTime, 2) + ':' + RIGHT(LEFT(@stringTime, 4), 2) AS TIME) as TimeValue

我绝对希望将此字段更改为实际时间或日期时间字段，因为不建议进行这种级别的转换，特别是对于频繁使用的数据库。确实需要有一种更好的方法来存储数据。

以这种方式使用 int 值会产生大量错误数据，而无需对输入添加大量额外的检查和/或约束（即：260000、127900 等）

Answer 2

看起来您需要除以 100 来获取秒，除以 10000 来获取分钟，除以 1000000 来获取小时，然后将这些值格式化为字符串，在小时和分钟之间插入冒号，例如

时:分

Answer 3

首先转换为 varchar 字段，并将所有时间转换为 4 位数字，如果需要的话添加前导零（500 将变为 0500），然后使用串联 Left(myfield,2) + ':' + right(myfield,2) 分解该字段

每次运行报表时都这样做很愚蠢，会浪费服务器资源。如果可能，将该字段更改为 varchar 并运行代码一次。如果不可能，您可以添加一个格式化字段并让触发器在插入时进行格式化（您仍然需要第一次更新该字段吗？可能可以使用约束而不是触发器，但这取决于数据库。

Answer 4

根据 CONVERT 的使用以及您之前的问题，我假设您使用的是 SQL Server。

您也可以使用 DATEADD 来实现此目的。

WITH Times AS
(
SELECT 183000 AS T 
UNION ALL 
SELECT 500 
UNION ALL  
SELECT 160000 

)
SELECT CAST(DATEADD(SECOND, T%100 + (60*(T%10000 / 100)) + 3600*(T/10000),0)
            AS time /*Or datetime if < SQL Server 2008*/)
FROM Times

Answer 5

declare @i int = 235959

select cast(stuff(stuff(
                case when len(cast(@i as varchar(6))) = 6 then cast(@i as varchar(6)) 
                     else REPLICATE('0',6 - LEN(cast(@i as varchar(6))))+cast(@i as varchar(6)) 
                end
            ,3,0,':'), 6, 0,':') as datetime)

set @i = 500

select cast(stuff(stuff(
                case when len(cast(@i as varchar(6))) = 6 then cast(@i as varchar(6)) 
                     else REPLICATE('0',6 - LEN(cast(@i as varchar(6))))+cast(@i as varchar(6)) 
                end
            ,3,0,':'), 6, 0,':') as datetime)

Answer 6

DECLARE @intTime int
SET @intTime = 50000
SELECT CAST(STUFF(STUFF(CONCAT(REPLICATE('0', 6 - LEN(@intTime)),@intTime),3,0,':'),6,0,':') AS TIME(0))

Answer 7

ALTER FUNCTION [dbo].[MinutesToDuration]
(
    @minutes int 
)
RETURNS nvarchar(30)

AS
BEGIN
declare @hours  nvarchar(20)
DECLARE @XX NVARCHAR(10) 
DECLARE @HH  VARCHAR(2)
DECLARE @TT  VARCHAR(2)
DECLARE @BL   NVARCHAR(2)
DECLARE @TM  VARCHAR(5)

SET @XX=@minutes
IF @XX<60
    BEGIN
    IF @XX<10
        BEGIN
        SET @HH='00'
        SET @TT='0'+@XX
        END
    ELSE
        BEGIN
        SET @HH='00'
        SET @TT=@XX
        END
END
ELSE
BEGIN
    IF @XX%60=0
    BEGIN
    SET @HH=@XX/60
    SET @TT='00'
    END
    ELSE
        BEGIN
            SET @BL= @XX%60
            IF @BL<10
                BEGIN
                SET @HH=@XX/60
                SET @TT='0'+@BL
                END     
            ELSE
                BEGIN
                SET @HH=@XX/60
                SET @TT=@BL
                END
        END
END

SET @hours= @HH+':'+@TT

return @hours
END