更通用的 Lisp 代码来生成对的组合

Question

考虑到下面这个悲伤的事情，它生成仅两个范围的所有对 -

[53]> (setq thingie '())

NIL
[54]> (loop for i in (generate-range 0 3) do 
(loop for j in (generate-range 4 6) do 
(push (list i j) thingie)))

NIL
[55]> thingie

((3 6) (3 5) (3 4) (2 6) (2 5) (2 4) (1 6) (1 5) (1 4) (0 6) (0 5) (0 4))
[56]>  

或者，换句话说，这会生成某种二维离散布局。

我将如何构建某种采用任意范围数量的对生成代码？ （或者生成一个n维离散布局）。

显然，一个解决方案是使用一个 defmacro 来获取列表列表并构建 n 个循环来执行，但这感觉不是一个简单的方法。

Answer 1

(defun map-cartesian (fn bags)
  (labels ((gn (x y)
             (if y (mapc (lambda (i) (gn (cons i x) (cdr y))) (car y))
                 (funcall fn x))))
    (gn nil (reverse bags))))

CL-USER> (map-cartesian #'print '((1 2) (a b c) (x y)))

(1 A X) 
(2 A X) 
(1 B X) 
(2 B X) 
(1 C X) 
(2 C X) 
(1 A Y) 
(2 A Y) 
(1 B Y) 
(2 B Y) 
(1 C Y) 
(2 C Y) 

如果您更喜欢语法糖，

(defmacro do-cartesian ((item bags) &body body)
  `(map-cartesian (lambda (,item) ,@body) ,bags))

CL-USER> (do-cartesian (x '((1 2) (a b c) (x y)))
           (print x))

请编辑：（简要说明）

gn 的第一个参数 x 是迄今为止构造的部分元组； y 是剩余的元素袋。函数 gn 通过迭代剩余包之一 (car y) 的每个元素 i 来扩展部分元组，以形成 (cons ix)。当没有剩余的包时（if语句的else分支），元组就完成了，因此我们在元组上调用提供的函数fn。

Answer 2

对我来说显而易见的是递归函数。

Answer 3

如果您将其视为一种控制结构，那么宏路线就是正确的选择。如果您将其视为生成数据的一种方式，那么递归函数就是最佳选择。

Answer 4

您不需要显式递归（甚至不需要宏），这也可以使用高阶函数来完成：

(defun tuples-from-ranges (range &rest ranges)
  (reduce (lambda (acc range)
            (mapcan (lambda (sublist)
                      (mapcar (lambda (elt)
                                (append sublist (list elt)))
                              (apply #'generate-range range)))
                    acc))
          ranges
          :initial-value (mapcar #'list (apply #'generate-range range))))

两个嵌套的内部高阶函数（mapcan 和 mapcar) 执行与示例中的两个嵌套循环相同的功能。然后，外部高阶函数reduce将首先将前两个范围的值组合成对，然后在每次调用其参数函数时再次将某个过程应用于前面的中间结果调用和下一个范围。