如何检查某个键是否存在于深层 Perl 哈希中？

Question

如果我理解正确，调用 if (exists $ref->{A }->{B}->{$key}) { ... } 将出现 $ref->{A} 和 $ref- >{A}->{B} 即使它们在 if 之前不存在！

这似乎是非常不受欢迎的。那么我应该如何检查“深层”哈希键是否存在？

Answer 1

最好使用 autovivification 模块来关闭该功能，或者使用 Data::Diver。然而，这是我希望程序员知道如何自己完成的简单任务之一。即使您在这里不使用该技术，您也应该知道它可以解决其他问题。这本质上就是 Data::Diver 剥离其接口后所做的事情。

一旦你掌握了遍历数据结构的技巧（如果你不想使用为你做这件事的模块），这很容易。在我的示例中，我创建了一个 check_hash 子例程，该子例程采用哈希引用和要检查的键的数组引用。它一次检查一个级别。如果密钥不存在，则不会返回任何内容。如果密钥存在，它将哈希修剪为路径的该部分，并再次尝试使用下一个密钥。诀窍在于 $hash 始终是树中要检查的下一个部分。我将 exists 放入 eval 中，以防下一个级别不是哈希引用。诀窍是如果路径末尾的哈希值是某种错误值，则不会失败。这是任务的重要部分：

sub check_hash {
   my( $hash, $keys ) = @_;

   return unless @$keys;

   foreach my $key ( @$keys ) {
       return unless eval { exists $hash->{$key} };
       $hash = $hash->{$key};
       }

   return 1;
   }

不要被接下来的所有代码吓到。重要的部分就是 check_hash 子例程。其他一切都是测试和演示：

#!perl
use strict;
use warnings;
use 5.010;

sub check_hash {
   my( $hash, $keys ) = @_;

   return unless @$keys;

   foreach my $key ( @$keys ) {
       return unless eval { exists $hash->{$key} };
       $hash = $hash->{$key};
       }

   return 1;
   }

my %hash = (
   a => {
       b => {
           c => {
               d => {
                   e => {
                       f => 'foo!',
                       },
                   f => 'foo!',
                   },
               },
           f => 'foo!',
           g => 'goo!',
           h => 0,
           },
       f => [ qw( foo goo moo ) ],
       g => undef,
       },
   f => sub { 'foo!' },
   );

my @paths = (
   [ qw( a b c d     ) ], # true
   [ qw( a b c d e f ) ], # true
   [ qw( b c d )       ], # false
   [ qw( f b c )       ], # false
   [ qw( a f )         ], # true
   [ qw( a f g )       ], # false
   [ qw( a g )         ], # true
   [ qw( a b h )       ], # false
   [ qw( a )           ], # true
   [ qw( )             ], # false
   );

say Dumper( \%hash ); use Data::Dumper; # just to remember the structure    
foreach my $path ( @paths ) {
   printf "%-12s --> %s\n", 
       join( ".", @$path ),
       check_hash( \%hash, $path ) ? 'true' : 'false';
   }

这是输出（减去数据转储）：

a.b.c.d      --> true
a.b.c.d.e.f  --> true
b.c.d        --> false
f.b.c        --> false
a.f          --> true
a.f.g        --> false
a.g          --> true
a.b.h        --> true
a            --> true
             --> false

现在，您可能需要进行一些其他检查，而不是 exists。也许您想检查所选路径的值是否为真，或者是字符串，或者另一个散列引用，或者其他什么。只需在验证路径存在后提供正确的检查即可。在此示例中，我传递了一个子例程引用，它将检查我留下的值。我可以检查我喜欢的任何内容：

#!perl
use strict;
use warnings;
use 5.010;

sub check_hash {
    my( $hash, $sub, $keys ) = @_;

    return unless @$keys;

    foreach my $key ( @$keys ) {
        return unless eval { exists $hash->{$key} };
        $hash = $hash->{$key};
        }

    return $sub->( $hash );
    }

my %hash = (
    a => {
        b => {
            c => {
                d => {
                    e => {
                        f => 'foo!',
                        },
                    f => 'foo!',
                    },
                },
            f => 'foo!',
            g => 'goo!',
            h => 0,
            },
        f => [ qw( foo goo moo ) ],
        g => undef,
        },
    f => sub { 'foo!' },
    );

my %subs = (
    hash_ref  => sub {   ref $_[0] eq   ref {}  },
    array_ref => sub {   ref $_[0] eq   ref []  },
    true      => sub { ! ref $_[0] &&   $_[0]   },
    false     => sub { ! ref $_[0] && ! $_[0]   },
    exist     => sub { 1 },
    foo       => sub { $_[0] eq 'foo!' },
    'undef'   => sub { ! defined $_[0] },
    );

my @paths = (
    [ exist     => qw( a b c d     ) ], # true
    [ hash_ref  => qw( a b c d     ) ], # true
    [ foo       => qw( a b c d     ) ], # false
    [ foo       => qw( a b c d e f ) ], # true
    [ exist     => qw( b c d )       ], # false
    [ exist     => qw( f b c )       ], # false
    [ array_ref => qw( a f )         ], # true
    [ exist     => qw( a f g )       ], # false
    [ 'undef'   => qw( a g )         ], # true
    [ exist     => qw( a b h )       ], # false
    [ hash_ref  => qw( a )           ], # true
    [ exist     => qw( )             ], # false
    );

say Dumper( \%hash ); use Data::Dumper; # just to remember the structure    
foreach my $path ( @paths ) {
    my $sub_name = shift @$path;
    my $sub = $subs{$sub_name};
    printf "%10s --> %-12s --> %s\n", 
        $sub_name, 
        join( ".", @$path ),
        check_hash( \%hash, $sub, $path ) ? 'true' : 'false';
    }

及其输出：

     exist --> a.b.c.d      --> true
  hash_ref --> a.b.c.d      --> true
       foo --> a.b.c.d      --> false
       foo --> a.b.c.d.e.f  --> true
     exist --> b.c.d        --> false
     exist --> f.b.c        --> false
 array_ref --> a.f          --> true
     exist --> a.f.g        --> false
     undef --> a.g          --> true
     exist --> a.b.h        --> true
  hash_ref --> a            --> true
     exist -->              --> false

Answer 2

您可以使用 autovivification 编译指示来停用引用的自动创建：

use strict;
use warnings;
no autovivification;

my %foo;
print "yes\n" if exists $foo{bar}{baz}{quux};

print join ', ', keys %foo;

它也是词汇的，这意味着它只会在您指定的范围内停用它。

Answer 3

在查看顶层之前检查每个级别是否存在。

if (exists $ref->{A} and exists $ref->{A}{B} and exists $ref->{A}{B}{$key}) {
}

如果您觉得这很烦人，您可以随时查看 CPAN。例如，有 Hash::NoVivify。

Answer 4

查看 Data::Diver。例如：

use Data::Diver qw(Dive);

my $ref = { A => { foo => "bar" } };
my $value1 = Dive($ref, qw(A B), $key);
my $value2 = Dive($ref, qw(A foo));

Answer 5

相当丑陋，但如果 $ref 是一个复杂的表达式，您不想在重复的存在测试中使用：

if ( exists ${ ${ ${ $ref || {} }{A} || {} }{B} || {} }{key} ) {