谁能发现这个 VB.Net 代码的问题吗？

Question

我正在 VB.Net 中编写一些代码，我希望向同事演示（更不用说让自己更加熟悉）各种设计模式 - 我对 FactoryMethod 模式有疑问。

这是我的代码：

Namespace Patterns.Creational.FactoryMethod

    ''' <summary>
    ''' This is the Factory bit - the other classes are merely by way of an example...
    ''' </summary>
    Public Class CarFactory
        ''' <summary>
        ''' CreateCar could have been declared as Shared (in other words,a Class method) - it doesn't really matter.
        ''' Don't worry too much about the contents of the CreateCar method - the point is that it decides which type
        ''' of car should be created, and then returns a new instance of that specific subclass of Car.
        ''' </summary>
        Public Function CreateCar() As Car
            Dim blnMondeoCondition As Boolean = False
            Dim blnFocusCondition As Boolean = False
            Dim blnFiestaCondition As Boolean = False

            If blnMondeoCondition Then
                Return New Mondeo()
            ElseIf blnFocusCondition Then
                Return New Focus()
            ElseIf blnFiestaCondition Then
                Return New Fiesta()
            Else
                Throw New ApplicationException("Unable to create a car...")
            End If

        End Function
    End Class

    Public MustInherit Class Car
        Public MustOverride ReadOnly Property Price() As Decimal
    End Class

    Public Class Mondeo Inherits Car

        Public ReadOnly Overrides Property Price() As Decimal
            Get
                Return 17000
            End Get
        End Property
    End Class

    Public Class Focus Inherits Car
        Public ReadOnly Overrides Property Price() As Decimal
            Get
                Return 14000
            End Get
        End Property
    End Class

    Public Class Fiesta Inherits Car
        Public ReadOnly Overrides Property Price() As Decimal
            Get
                Return 12000
            End Get
        End Property
    End Class

End Namespace

当我尝试编译此代码时，我在 CarFactory.CreateCar 中收到错误 (BC30311)，告诉我它无法将嘉年华、蒙迪欧和福克斯转换为汽车。我不明白问题是什么 - 它们都是 Car 的子类。

毫无疑问，我忽略了一些简单的事情。有人能发现吗？

干杯，

马丁。

Answer 1

将 Inherits 放在新行或使用 : 分隔类名和 Inherits 语句：

Public Class Mondeo
    Inherits Car
...


Public Class Focus
    Inherits Car
...


Public Class Fiesta
    Inherits Car
...

Answer 2

您的 Inherits 关键字必须换行。 Microsoft 在其帮助和支持中记录了这一点。 http://support.microsoft.com/kb/307222

更改 SavingsAccount 类
定义如下，使得
SavingsAccount 继承自 Account
（请注意，Inherits 关键字必须
出现在新行上）：

Answer 3

列表中的第一个错误只是最低行号的错误，它并不总是错误的实际原因。

在错误列表的更下方，您将在每个子类中看到（以及其他几个）另外三个错误，内容为 End ofstatementexpected.。这是因为 Class 和 Inherits 是单独的语句，并且位于不同的行上：

Public Class Mondeo
  Inherits Car

或者：

Public Class Mondeo : Inherits Car

当您修复这些错误时，这些类实际上是从 Car 继承的>，你的代码就可以工作了。