是否可以将汇编指令放入 CUDA 代码中？

Question

我想在 CUDA C 代码中使用汇编代码 为了减少昂贵的执行 就像我们在 C 编程中使用 asm 一样。

是否可以？

Answer 1

自 CUDA 4.0 起，CUDA 工具链支持内联 PTX。工具包中有一个文档对其进行了描述：Using_Inline_PTX_Assembly_In_CUDA.pdf

下面是一些演示在 CUDA 4.0 中使用内联 PTX 的代码。请注意，此代码不应用作 CUDA 内置 __clz() 函数的替代品，我编写它只是为了探索新的内联 PTX 功能的各个方面。

__device__ __forceinline__ int my_clz (unsigned int x)
{
    int res;

    asm ("{\n"
         "        .reg .pred iszero, gezero;\n"
         "        .reg .u32 t1, t2;\n"
         "        mov.b32         t1, %1;\n"
         "        shr.u32         %0, t1, 16;\n"
         "        setp.eq.b32     iszero, %0, 0;\n"
         "        mov.b32         %0, 0;\n"
         "@iszero shl.b32         t1, t1, 16;\n"
         "@iszero or.b32          %0, %0, 16;\n"
         "        and.b32         t2, t1, 0xff000000;\n"
         "        setp.eq.b32     iszero, t2, 0;\n"
         "@iszero shl.b32         t1, t1, 8;\n"
         "@iszero or.b32          %0, %0, 8;\n"
         "        and.b32         t2, t1, 0xf0000000;\n"
         "        setp.eq.b32     iszero, t2, 0;\n"
         "@iszero shl.b32         t1, t1, 4;\n"
         "@iszero or.b32          %0, %0, 4;\n"
         "        and.b32         t2, t1, 0xc0000000;\n"
         "        setp.eq.b32     iszero, t2, 0;\n"
         "@iszero shl.b32         t1, t1, 2;\n"
         "@iszero or.b32          %0, %0, 2;\n"
         "        setp.ge.s32     gezero, t1, 0;\n"
         "        setp.eq.b32     iszero, t1, 0;\n"
         "@gezero or.b32          %0, %0, 1;\n"
         "@iszero add.u32         %0, %0, 1;\n\t"
         "}"
         : "=r"(res)
         : "r"(x));
    return res;
}

Answer 2

不，你不能，没有什么比 C/C++ 的 asm 构造更好的了。您可以做的是调整生成的 PTX 程序集，然后将其与 CUDA 一起使用。

有关示例，请参阅此。

但对于GPU来说，装配优化不是必需的，你应该先做其他优化，比如内存合并和占用。请参阅CUDA 最佳实践指南了解更多信息。