使用 shellscript 更改随机行

Question

我如何使用简单的 shellscript 轻松（快速而肮脏地）更改文件的随机行（例如 10 行）？

我想滥用 ed 并生成随机命令和行范围，但我想知道是否有更好的方法

Answer 1

awk 'BEGIN{srand()}
{ lines[++c]=$0 }
END{
  while(d<10){
   RANDOM = int(1 + rand() * c)
   if( !( RANDOM in r)  ) {
     r[RANDOM]
     print "do something with " lines[RANDOM]
     ++d
   }
  }
}' file

或者如果您有 shuf 命令

shuf -n 10 $file | while read -r line
do
  sed -i "s/$line/replacement/" $file
done

Answer 2

使用 @Dennis 的版​​本，这将始终输出 10。
在单独的数组中执行随机数可能会创建
重复，因此修改次数少于 10 次。

file=~/testfile
c=$(wc -l < "$file")
awk -v c=$c '
BEGIN {
        srand();
        count = 10;
    }

    {
        if (c*rand() < count) {
            --count;
            print "do something with " $0;
        } else
            print;
        --c;
    }
' "$file"

Answer 3

这似乎要快一些：

file=/your/input/file
c=$(wc -l < "$file")
awk -v c=$c 'BEGIN {
                    srand();
                    for (i=0;i<10;i++) lines[i] = int(1 + rand() * c);
                    asort(lines);
                    p = 1
             }
             {
                 if (NR == lines[p]) {
                     ++p
                     print "do something with " $0
                 }
                 else print 
             }' "$file"

我