如何在 Perl 中使用 Getopt::Long 验证读取了哪些标志？

Question

myscript.pl

my $R;
my $f1 = "f1.log";
my $f2 = "f2.log";
my $f3 = "f3.log";

sub checkflags {

    GetOptions('a=s'    => \$f1,
               'b=s'    => \$f2,
               'c=s'    => \$f3,
    );

    open $R, '>', $f1 or die "Cannot open file\n"; # Line a
}

• 所有标志都是可选的。

• 如果我将脚本称为

  perl myscript.pl -a=文件名
  

  我需要在文件名中附加一个.log，然后才能在Line a处打开它。

• 为此，我需要知道 GetOptions 是否将某些内容读入 $f1 中。

这怎么能做到呢？

Answer 1

最简单的解决方案是在 $f1 中查找 /[.]log$/ ，如果不存在则添加它。不幸的是，这意味着当用户传入 "foo.log" 并希望它成为 "foo.log.log" 时，它不会，但我认为我们可以同意用户是个混蛋。

一个更好的选择是：

#!/usr/bin/perl

use strict;
use warnings;

use Getopt::Long;

GetOptions(
    'a=s'    => \my $f1,
    'b=s'    => \my $f2,
    'c=s'    => \my $f3,
);

if (defined $f1) {
    $f1 .= ".log";
} else {
    $f1 = "f1.log";
}

print "$f1\n";

如果你想在顶部定义所有默认名称，请使用不同的变量来做到这一点（无论如何，阅读代码可能会更好）：

#!/usr/bin/perl

use strict;
use warnings;

use Getopt::Long;

my $default_f1 = "f1.log";
my $default_f2 = "f2.log";
my $default_f3 = "f3.log";

GetOptions(
    'a=s'    => \my $f1,
    'b=s'    => \my $f2,
    'c=s'    => \my $f3,
);

if (defined $f1) {
    $f1 .= ".log";
} else {
    $f1 = $default_f1;
}

print "$f1\n";

Answer 2

if (defined $f1) {
  # You got a -a option
}

但我个人更喜欢 将选项读入哈希，然后使用exists()。

Answer 3

$f1 = "$f1.log" unless $f1 =~ m/\.log$/i;

如果文件名尚无扩展名，则附加 log 扩展名。由于默认值以 log 结尾，因此不会发生任何情况。如果用户在命令行上输入log，它就会起作用。

Answer 4

实现此目的的一种方法是使用 Moose 和 MooseX::Getopt:

package MyApp;

use strict;
use warnings;

use Moose;
with 'MooseX::Getopt';

has f1 => (
    is => 'ro', isa => 'Str',
    cmd_aliases => 'a',
    default => 'f1.log',
    predicate => 'has_a',
);
has f2 => (
    is => 'ro', isa => 'Str',
    cmd_aliases => 'b',
    default => 'f2.log',
    predicate => 'has_b',
);
has f3 => (
    is => 'ro', isa => 'Str',
    cmd_aliases => 'c',
    default => 'f3.log',
    predicate => 'has_c',
);

# this is run immediately after construction
sub BUILD
{
    my $this = shift;

    print "a was provided\n" if $this->has_a;
    print "b was provided\n" if $this->has_b;
    print "c was provided\n" if $this->has_c;
}

1;