从 Delphi DLL 导出全局符号

Question

我正在尝试在 Delphi 中创建一个与 Gecko 2.0 兼容的 DLL。

以前（Gecko 2.0 之前）DLL 需要导出 NSGetModule() 函数。这工作完美无缺。

从 Firefox 4 开始，我的 DLL 正在加载（我已经通过初始化部分中的断点验证了这一点），但我的 NSGetModule() 函数不再被调用。这是设计行为，因为从 Gecko 2.0 (Firefox 4) 开始，二进制组件不应导出 NSGetModule() 函数：

https://developer.mozilla.org/en/XPCOM/XPCOM_changes_in_Gecko_2.0#Binary_components

根据这些文档，我的 DLL 需要导出一个 NSModule 数据符号，该符号指向到一个结构体。在 Delphi 术语中，我假设这是一个指向 Delphi 记录的全局变量。

在 C++ 中，这就是导出（全局）数据符号的方式：

define NSMODULE_DEFN(_name) extern "C" NS_EXPORT mozilla::Module const *const NSModule

我的问题：如何在 Delphi 中完成此操作？如何导出全局变量？

感谢您的反馈。

Answer 1

Delphi 从 DLL 导出全局变量的方式与导出函数的方式类似：

library exp;
var
  global: Integer;
exports global;
end.

Delphi 可以从 DLL 导入全局变量，但这有点麻烦：声明一个与要导入的全局同名的 DLL 导入过程，然后获取程序的地址并进行适当调整。从Delphi 的角度来看，DLL 导入过程是通过DLL 导入表进行间接跳转的存根。导出的变量由操作系统加载器通过将导出的全局地址放入导入表中进行链接，几乎与导出过程的地址的修补方式完全相同。

例如：

{$apptype console}

procedure global; external 'exp.dll';

function GetGlobalAddr: PInteger;
type
  PPPointer = ^PPointer;
var
  p: PByte;
begin
  p := @global;
  Assert(p^ = $FF); // $FF $25 => indirect jump m32
  Inc(p);
  Assert(p^ = $25);
  Inc(p);
  Result := PPPointer(p)^^
end;

begin
  Writeln(GetGlobalAddr^);
end.

当然，后者的细节取决于实现和平台等。也许更安全的方法是将 LoadLibrary 与 GetProcAddress 一起使用，这将在传递全局变量的名称时返回全局变量的地址。当然，这也依赖于平台。

64 位更新：

在 Windows 上的 64 位中，代码略有不同。操作码相同，但同一指令序列的寻址方式不同；它不是 32 位绝对偏移，而是 32 位相对偏移。

function GetGlobalAddr: PInteger;
type
  PPPointer = ^PPointer;
var
  p: PByte;
  ofs: Integer;
begin
  p := @global;
  Assert(p^ = $FF); // $FF $25 => indirect jump m32
  Inc(p);
  Assert(p^ = $25);
  Inc(p);
  // 32-bit offset follows
  ofs := PInteger(p)^;
  // offset is relative to next instruction
  Inc(p, SizeOf(ofs) + ofs);
  Result := PPPointer(p)^^
end;

Answer 2

阅读文档，我认为 Delphi 不允许直接导出全局变量，因为导出语句的帮助仅讨论例程。还有一个非常明确的

在共享中声明的全局变量
Delphi 无法导入库
应用程序。

并且可以安全地假设，如果 Delphi 无法导入它们，它也不会导出它们。

我想解决这个问题的方法可能是导出一个返回指向全局变量的指针的函数...

仅此几行：

type
  RGlobalRecord = record
    ...
  end;
  PGlobalRecord = ^RGlobalRecord;

var
  _GlobalRecord: RGlobalRecord;

function GetGlobalRecord: PGlobalRecord;
begin
  Result := @_GlobalRecord;
end;

exports GetGlobalRecord name 'ExternalNameOfGlobalRecord';

所以，如果 NSGetModule 函数返回与您现在需要导出为全局变量相同的结构，您可以尝试使用要导出的全局变量所需的名称来导出该函数：

exports NSGetModule name 'NSModule';

Answer 3

这是我的德尔福解决方案。即使在 D5 中它也能工作:)

function MyComponentConstructor(aOuter: nsISupports; const IID: TGUID; out _result): nsresult; cdecl;
begin
  /* constructor */
end;


type
  TCIDEntry = record
    cid: ^TGUID;
    service: Boolean;
    getFactoryProc: Pointer;
    constructorProc: Pointer;
  end;

  TContractIDEntry = record
    constractid: PChar;
    cid: ^TGUID;
  end;

  TCategoryEntry = record
    category: PChar;
    entry: PChar;
    value: PChar;
  end;

  TModule = packed record
    mVersion: DWord;
    mCIDs: array of TCIDEntry;
    mContractIDs: array of TContractIDEntry;
    mCategoryEntries: array of TCategoryEntry;
    getFactoryProc: Pointer;
    loadProc: Pointer;
    unloadProc: Pointer;
  end;

  PModule = ^TModule;
  PPModule = ^PModule;

var
  mCIDs: array [0..1] of TCIDEntry =
  (
    ( cid: @Sample_cid; service: False; getFactoryProc: nil; constructorProc: @MyComponentConstructor ),
    ( cid: nil; service: False; getFactoryProc: nil; constructorProc: nil )
  );

  mContractIDs: array [0..1] of TContractIDEntry =
  (
    ( constractid: Sample_CONTRACTID; cid: @Sample_cid ),
    ( constractid: nil; cid: nil )
  );

  mCategoryEntries: array [0..2] of TCategoryEntry =
  (
    ( category: 'JavaScript-global-property'; entry: 'MyComponent'; value: Sample_CONTRACTID ),
    ( category: 'JavaScript-global-constructor'; entry: 'MyComponent'; value: Sample_CONTRACTID ),
    ( category: nil; entry: nil; value: nil )
  );

  NSModuleElem: TModule =
    (
       mVersion: 1;
       mCIDs: @mCIDs;
       mContractIDs: @mContractIDs;
       mCategoryEntries: @mCategoryEntries;
       getFactoryProc: nil;
       loadProc: nil;
       unloadProc: nil
    );

  NSModule: PModule = Addr(NSModuleElem);

exports
  NSModule name 'NSModule';

现在如果你可以向我发送 Delphi 中的 GenericClassInfo 实现，那就太棒了:)

Answer 4

正如您所注意到的，这在 FF 5 和 FF 6 中不起作用。相反，您可以添加初始化块来在运行时检查 Firefox 版本，并相应地调整 mVersion。
Mozilla 有意破坏二进制组件，因此即使在不同版本之间，这也是一个可行的解决方法。

您可以使用 Application.ExeName 和 http://www.delphitricks.com/source- code/files/get_the_version_of_a_file.html

FF 5 - mVersion := 2;

FF 6 - m版本 := 6;

FF 7 - m版本 := 7;

Answer 5

这是我当前的实现（这适用于 FF 5 和 FF 6 以及可能未来的所有其他版本）

type
  TCIDEntry = record
    CID: PGUID;
    Service: BOOL;
    GetFactoryProc: Pointer;
    ConstructorProc: Pointer;
  end;

  TContract = record
    ContractID: PChar;
    CID: PGUID;
  end;

  TCategory = record
    Category: PChar;
    Entry: PChar;
    Value: PChar;
  end;

  TModule = record
    Version: UINT;
    CIDs: Pointer;
    Contracts: Pointer;
    Categories: Pointer;
    GetFactory: Pointer;
    Load: Pointer;
    Unload: Pointer;
  end;

  PModule = ^TModule;

var
  NSModule: PModule;

implementation

var
  mtModule: TModule;
  CIDs: array[0..1] of TCIDEntry;
  Contracts: array[0..1] of TContract;

function GetFileVersionResourceInfo(const FileName, VerValue: string): string;
var
  S: string;
  Value: Pointer;
  ValueSize: DWORD;
  VerInfoSize: DWORD;
  VersionInfo: Pointer;
  GetInfoSizeJunk: DWORD;
begin
  // retrieve the size of the version information resource
  VerInfoSize := GetFileVersionInfoSize(PChar(FileName), GetInfoSizeJunk);
  if VerInfoSize > 0 then
  begin
    // retrieve memory to hold the version resource
    GetMem(VersionInfo, VerInfoSize);
    try
      // retrieve the version resource
      if GetFileVersionInfo(PChar(FileName), 0, VerInfoSize, VersionInfo) then
        if VerQueryValue(VersionInfo, '\\VarFileInfo\\Translation', Value, ValueSize) then
        begin
          S := '\\StringFileInfo\\' +
          IntToHex(LoWord(LongInt(Value^)), 4) +
          IntToHex(HiWord(LongInt(Value^)), 4) + '\\';
          if VerQueryValue(VersionInfo, PChar(S + VerValue), Value, ValueSize) then Result := PChar(Value);
        end;
    finally
      FreeMem(VersionInfo, VerInfoSize);
    end;
  end;
end;

function GetVersion: Integer;
var
  I: Integer;
  sProductVersion: string;
  sModuleFileName: array[0..MAX_PATH] of Char;
begin
  Result := 1; // Firefox 4
  FillChar(sModuleFileName, MAX_PATH, 0);
  if GetModuleFileName(0, sModuleFileName, SizeOf(sModuleFileName)) > 0 then
  begin
    sProductVersion := Trim(GetFileVersionResourceInfo(sModuleFileName, 'ProductVersion'));
    if (sProductVersion <> '') and (sProductVersion[1] in ['4'..'9']) then
    begin
      // Firefox 4 = version 1
      // Firefox 5 = version 2
      // Firefox 6 = version 6
      // etc.
      I := StrToInt(sProductVersion[1]);
      if I <= 5 then
        Result := I - 3
      else
        Result := I;
    end;
  end;
end;

function MyConstructor(aOuter: nsISupports; const aIID: TGUID; out aResult): nsresult; cdecl;
begin

end;

initialization
  mtModule.Version := GetVersion;

  CIDs[0].CID := @Sample_CID;
  CIDs[0].ConstructorProc := @MyConstructor;
  mtModule.CIDs := @CIDs;

  Contracts[0].ContractID := Sample_CONTRACTID;
  Contracts[0].CID := @Sample_CID;
  mtModule.Contracts := @Contracts;

  NSModule := @mtModule;

end.