除对话框外的 AppleScript GUI 元素

Question

我想知道 AppleScript 中是否有一种方法可以创建一个小型 Applet，而不必使用一堆对话框，我认为最终会更好。

这是我目前拥有的脚本，由 AppleScript Wikia 提供

set x1 to text returned of (display dialog "What is X1?" default answer "")
set y1 to text returned of (display dialog "What is Y1?" default answer "")
set x2 to text returned of (display dialog "What is X2?" default answer "")
set y2 to text returned of (display dialog "What is Y2?" default answer "")
display dialog "Distance = " & ((x2 - x1) ^ 2 + (y2 - y1) ^ 2) ^ (1 / 2)

现在，显然，我理解这个脚本，因为它非常简单！

但我想知道，如果像这样的小 Applet 更有用和实用一点，那么最好有某种窗口，而不用一堆对话框来打扰用户。

有没有一种方法可以构建一个带有输入字段和“计算”按钮或类似内容的窗口。

或者，此时，构建一个超级简单的 Objective-C 应用程序会更好吗？

Answer 1

Applescript 只提供与用户的非常基本的交互，超出了您在那里显示的内容。 Xcode 支持创建带有 GUI 前端和 Applescript 后端的简单应用程序。 新建项目>Mac OS X>应用程序>Applescript 应用程序。文档是有限的，在这一点上，如果您有 Cocoa 能力，我建议您只走这条路，以获得更轻松的长期支持。

Answer 2

您知道您可以在一个对话框而不是 4 个对话框中完成此操作...

set theValues to text returned of (display dialog "Enter X1 Y1 X2 Y2 separated by a space." default answer "")
set {tids, text item delimiters} to {text item delimiters, space}
set {x1, y1, x2, y2} to text items of theValues
set text item delimiters to tids
display dialog "Distance = " & ((x2 - x1) ^ 2 + (y2 - y1) ^ 2) ^ (1 / 2)

因此您只需一次输入所有值，每个值之间留一个空格。然后在代码中将其分离到变量中。如果您的价值观始终是积极的，那么您只需获取价值观的“单词”即可使其变得更加简单。但如果您还想使用负值，我会坚持使用文本项分隔符。使用“words”可以去掉数字中的“-”符号。

如果您想变得非常奇特，您可以让用户将每个值放在单独的行上，如下所示...

set theValues to text returned of (display dialog "Enter X1 Y1 X2 Y2 on separate lines." default answer (return & return & return))
set {x1, y1, x2, y2} to paragraphs of theValues
display dialog "Distance = " & ((x2 - x1) ^ 2 + (y2 - y1) ^ 2) ^ (1 / 2)

解释文本项分隔符：
您可以通过获取字符串的“文本项”将字符串转换为列表。有一个称为“文本项定界符”(tids) 的值，它确定如何将该字符串分解为列表。默认情况下，tids 是“”（例如什么都没有）。例如，看看这个脚本...

set theString to "some text words"
set theList to text items of theString
--> {"s", "o", "m", "e", " ", "t", "e", "x", "t", " ", "w", "o", "r", "d", "s"}

您获得的列表是将字符串的每个字符作为单独的项目。这是因为tids是“”的默认值。现在让我们看看如果我们将 tid 更改为其他内容会发生什么。让我们将 tid 设为空格字符，然后再次运行脚本...

set theString to "some text words"
set text item delimiters to space
set theList to text items of theString
--> {"some", "text", "words"}

通过将其设为空格，字符串将被分解为之间有空格的项目。所以你看我们可以通过控制tids来控制字符串如何变成列表。需要注意的一件事是：当我们将 tid 更改为默认值以外的值时，使用后我们必须将 tid 改回来。这是安全的编程，因为脚本的某些其他部分可能取决于 tid 的值。因此，请养成在完成后重置潮汐的习惯。这就是 tid 代码的基本功能。它存储tids的初始值（以便我们稍后可以将其更改回来），将tids更改为空格，使用tids将字符串转换为列表，然后将tids重置回其初始值。

我希望这有帮助。